NAG Library Manual, Mark 27.3
Interfaces:  FL   CL   CPP   AD 

NAG FL Interface Introduction
Example description
    Program f08gsfe

!     F08GSF Example Program Text

!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, zhptrd
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, info, j, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ap(:), tau(:)
      Real (Kind=nag_wp), Allocatable  :: d(:), e(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: abs
!     .. Executable Statements ..
      Write (nout,*) 'F08GSF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (ap(n*(n+1)/2),tau(n-1),d(n),e(n-1))

!     Read A from data file and copy a into AW

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

!     Reduce A to tridiagonal form
!     The NAG name equivalent of zhptrd is f08gsf
      Call zhptrd(uplo,n,ap,d,e,tau,info)

      If (info==0) Then
!       Print the diagonal and off-diagonal of tridiagonal T.
!       The absolute value of E is printed since this can vary by a change of
!       sign (corresponding to multiplying through a column of Q by -1).

        Write (nout,*)
        Write (nout,*)                                                         &
          'Diagonal and off-diagonal elements of tridiagonal form'
        Write (nout,*)
        Write (nout,99999) 'i', 'D', 'E'
        Do i = 1, n - 1
          Write (nout,99998) i, d(i), abs(e(i))
        End Do
        Write (nout,99998) n, d(n)

        Write (nout,99997) info
      End If

99999 Format (5X,A,9X,A,12X,A)
99998 Format (1X,I5,2(1X,F12.5))
99997 Format (1X,'** ZHPTRD/F08GSF retuned with INFO = ',I10)

    End Program f08gsfe