NAG Library Manual, Mark 29.3
Interfaces:  FL   CL   CPP   AD 

NAG AD Library Introduction
Example description
    Program f01ec_t1w_fe

!     F01EC_T1W_F Example Program Text

!     Mark 29.3 Release. NAG Copyright 2023.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f01ec_t1w_f, nagad_t1w_set_derivative,          &
                               nagad_t1w_w_rtype, x10aa_t1w_f, x10ab_t1w_f,    &
                               Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, j, lda, n
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: a(:,:), a_in(:,:)
      Real (Kind=nag_wp), Allocatable  :: a_r(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F01EC_T1W_F Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),a_in(lda,n),a_r(lda,n))
!     Read A from data file
      Read (nin,*)(a_r(i,1:n),i=1,n)
      a_in = a_r

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Call nagad_t1w_set_derivative(a_in(i,i),1.0_nag_wp)
        a = a_in
!       ifail: behaviour on error exit
!               =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
!       Find exp( A )
        Call f01ec_t1w_f(ad_handle,n,a,lda,ifail)
        If (i==1) Then
          a_r = a
!         Print solution
          Call x04caf('General',' ',n,n,a_r,lda,'Exp(A)',ifail)
        End If
        Do j = 1, n
          a_r(i,j) = a(j,j)%tangent
        End Do
        a_in(i,i)%tangent = 0.0_nag_wp
      End Do

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of diagonal of exp(A) w.r.t. diagonal of A'
      Write (nout,*)
      Call x04caf('General',' ',n,n,a_r,n,'       d(expA(i,i))/da(j,j)',ifail)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program f01ec_t1w_fe