NAG Library Manual, Mark 27.2
Interfaces:  FL   CL   CPP   AD 

NAG AD Library Introduction
Example description
!   E01DA_P0W_F Example Program Text
!   Mark 27.2 Release. NAG Copyright 2021.
    Program e01da_p0w_fe

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: e01da_p0w_f, e02de_p0w_f
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: ifail, j, m, mx, my, px, py
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: c(:), f(:,:), lamda(:), mu(:),       &
                                          wrk(:), x(:), y(:)
      Real (Kind=nag_wp)               :: ff(1), tx(1), ty(1)
      Integer, Allocatable             :: iwrk(:)
!     .. Executable Statements ..
      Write (nout,*) 'E01DA_P0W_F Example Program Results'

!     Skip heading in data file
      Read (nin,*)

!     Read the number of X points, MX, and the values of the
!     X co-ordinates.

      Read (nin,*) mx
      Allocate (x(mx),lamda(mx+4))

      Read (nin,*) x(1:mx)

!     Read the number of Y points, MY, and the values of the
!     Y co-ordinates.
      Read (nin,*) my

      Allocate (y(my),mu(my+4),c(mx*my),f(my,mx),wrk((mx+6)*(my+6)))
      Read (nin,*) y(1:my)

!     Read the function values at the grid points.
      Do j = 1, my
        Read (nin,*) f(j,1:mx)
      End Do

!     Call AD Interpolating Function routine
      ifail = 0
      Call e01da_p0w_f(ad_handle,mx,my,x,y,f,px,py,lamda,mu,c,wrk,ifail)

      Deallocate (wrk)

!     Interpolant to be evaluated at a single point
      m = 1
      tx(1) = 1.4_nag_wp
      ty(1) = 0.5_nag_wp

      Allocate (wrk(py-4),iwrk(py-4))

      ifail = 0
      Call e02de_p0w_f(ad_handle,m,px,py,tx,ty,lamda,mu,c,ff,wrk,iwrk,ifail)

      Write (nout,*)
      Write (nout,99999) tx(1), ty(1)
      Write (nout,99998) ff(1)
99999 Format (1X,' Spline fitted at point x = ',F6.2,' and y = ',F6.2)
99998 Format (1X,' Value of fitted spline   = ',F7.3)

    End Program e01da_p0w_fe