Program f08jufe

!     F08JUF Example Program Text

!     Mark 26.1 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: dznrm2, f06tff, nag_wp, x04dbf, zhetrd, zpteqr,   &
                             zungtr
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Complex (Kind=nag_wp)            :: scal
      Integer                          :: i, ifail, info, k, lda, ldz, lwork,  &
                                          n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), tau(:), work(:), z(:,:)
      Real (Kind=nag_wp), Allocatable  :: d(:), e(:), rwork(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: abs, conjg, maxloc
!     .. Executable Statements ..
      Write (nout,*) 'F08JUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      ldz = n
      lwork = 64*n
      Allocate (a(lda,n),tau(n),work(lwork),z(ldz,n),d(n),e(n),rwork(4*n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Reduce A to tridiagonal form T = (Q**H)*A*Q

!     The NAG name equivalent of zhetrd is f08fsf
      Call zhetrd(uplo,n,a,lda,d,e,tau,work,lwork,info)

!     Copy A into Z

      Call f06tff(uplo,n,n,a,lda,z,ldz)

!     Form Q explicitly, storing the result in Z

!     The NAG name equivalent of zungtr is f08ftf
      Call zungtr(uplo,n,z,ldz,tau,work,lwork,info)

!     Calculate all the eigenvalues and eigenvectors of A

!     The NAG name equivalent of zpteqr is f08juf
      Call zpteqr('V',n,d,e,z,ldz,rwork,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) d(1:n)
        Write (nout,*)
        Flush (nout)

!       Normalize the eigenvectors, largest element real
        Do i = 1, n
          rwork(1:n) = abs(z(1:n,i))
          k = maxloc(rwork(1:n),1)
          scal = conjg(z(k,i))/abs(z(k,i))/dznrm2(n,z(1,i),1)
          z(1:n,i) = z(1:n,i)*scal
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04dbf('General',' ',n,n,z,ldz,'Bracketed','F7.4','Eigenvectors', &
          'Integer',rlabs,'Integer',clabs,80,0,ifail)

      End If

99999 Format (8X,4(F7.4,11X,:))
    End Program f08jufe