!   F12ADF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE f12adfe_mod

!      F12ADF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER       :: four = 4.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: one = 1.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: six = 6.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: two = 2.0_nag_wp
       INTEGER, PARAMETER                  :: imon = 0, nin = 5, nout = 6
    CONTAINS
       SUBROUTINE mv(n,v)
!         Compute the in-place matrix vector multiplication X<---M*X,
!         where M is mass matrix formed by using piecewise linear elements
!         on [0,1].

!         .. Use Statements ..
          USE nag_library, ONLY : dscal
!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (IN)                :: n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: v(n)
!         .. Local Scalars ..
          REAL (KIND=nag_wp)                  :: h, vm1, vv
          INTEGER                             :: j
!         .. Intrinsic Functions ..
          INTRINSIC                              real
!         .. Executable Statements ..
          vm1 = v(1)
          v(1) = (four*v(1)+v(2))/six
          DO j = 2, n - 1
             vv = v(j)
             v(j) = (vm1+four*vv+v(j+1))/six
             vm1 = vv
          END DO
          v(n) = (vm1+four*v(n))/six

          h = one/real(n+1,kind=nag_wp)
!         The NAG name equivalent of dscal is f06edf
          CALL dscal(n,h,v,1)
          RETURN
       END SUBROUTINE mv
    END MODULE f12adfe_mod

    PROGRAM f12adfe

!      F12ADF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : dgttrf, dgttrs, dnrm2, f12aaf, f12abf, f12acf,  &
                               f12adf, f12aef
       USE f12adfe_mod, ONLY : four, imon, mv, nag_wp, nin, nout, one, six, two
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: h, rho, s, s1, s2, s3, sigmai,   &
                                              sigmar
       INTEGER                             :: ifail, ifail1, info, irevcm, j,  &
                                              lcomm, ldv, licomm, n, nconv,    &
                                              ncv, nev, niter, nshift, nx
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: comm(:), d(:,:), dd(:), dl(:),   &
                                              du(:), du2(:), mx(:), resid(:),  &
                                              v(:,:), x(:)
       INTEGER, ALLOCATABLE                :: icomm(:), ipiv(:)
!      .. Intrinsic Functions ..
       INTRINSIC                              real
!      .. Executable Statements ..
       WRITE (nout,*) 'F12ADF Example Program Results'
       WRITE (nout,*)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) nx, nev, ncv, rho, sigmar, sigmai
       n = nx*nx
       ldv = n
       licomm = 140
       lcomm = 3*n + 3*ncv*ncv + 6*ncv + 60
       ALLOCATE (comm(lcomm),d(ncv,3),dd(n),dl(n),du(n),du2(n),mx(n),resid(n), &
          v(ldv,ncv),x(n),icomm(licomm),ipiv(n))

!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL f12aaf(n,nev,ncv,icomm,licomm,comm,lcomm,ifail)

!      Set the mode.
       CALL f12adf('SHIFTED REAL',icomm,comm,ifail)
!      Set problem type
       ifail = 0
       CALL f12adf('GENERALIZED',icomm,comm,ifail)
!      Construct C = A - SIGMA*I, and factor C using DGTTRF/F07CDF.
       h = one/real(n+1,kind=nag_wp)
       s = rho/two
       s1 = -one/h - s - sigmar*h/six
       s2 = two/h - four*sigmar*h/six
       s3 = -one/h + s - sigmar*h/six
       dl(1:n-1) = s1
       dd(1:n-1) = s2
       du(1:n-1) = s3
       dd(n) = s2

!      The NAG name equivalent of dgttrf is f07cdf
       CALL dgttrf(n,dl,dd,du,du2,ipiv,info)

       irevcm = 0

       ifail = -1
LOOP:  DO
          CALL f12abf(irevcm,resid,v,ldv,x,mx,nshift,comm,icomm,ifail)

          IF (irevcm/=5) THEN
             SELECT CASE (irevcm)
             CASE (-1)
!               Perform  x <--- OP*x = inv[A-SIGMA*M]*M*x.
                CALL mv(n,x)
!               The NAG name equivalent of dgttrs is f07cef
                CALL dgttrs('N',n,1,dl,dd,du,du2,ipiv,x,n,info)
             CASE (1)
!               Perform  x <--- OP*x = inv[A-SIGMA*M]*M*x.
                CALL dgttrs('N',n,1,dl,dd,du,du2,ipiv,mx,n,info)
                x(1:n) = mx(1:n)
             CASE (2)
!               Perform  y <--- M*x
                CALL mv(n,x)
             CASE (4)
                IF (imon/=0) THEN
!                  Output monitoring information
                   CALL f12aef(niter,nconv,d,d(1,2),d(1,3),icomm,comm)
!                  The NAG name equivalent of dnrm2 is f06ejf
                   WRITE (6,99999) niter, nconv, dnrm2(nev,d(1,3),1)
                END IF
             END SELECT
          ELSE
             EXIT LOOP
          END IF
       END DO LOOP
       IF (ifail==0) THEN
!         Post-Process using F12ACF to compute eigenvalues/vectors.
          ifail1 = 0
          CALL f12acf(nconv,d,d(1,2),v,ldv,sigmar,sigmai,resid,v,ldv,comm, &
             icomm,ifail1)
!         Print computed eigenvalues.
          WRITE (nout,99998) nconv
          DO j = 1, nconv
             WRITE (nout,99997) j, d(j,1), d(j,2)
          END DO
       END IF

99999  FORMAT (1X,'Iteration',1X,I3,', No. converged =',1X,I3,', norm o', &
          'f estimates =',E16.8)
99998  FORMAT (1X/' The ',I4,' generalized Ritz values closest to ', &
          'unity are:'/)
99997  FORMAT (1X,I8,5X,'( ',F12.4,' , ',F12.4,' )')
    END PROGRAM f12adfe