PROGRAM f08wbfe

!      F08WBF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dggevx, f06bnf, nag_wp, x02ajf, x02amf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nb = 64, nin = 5, nout = 6
!      .. Local Scalars ..
       COMPLEX (KIND=nag_wp)           :: eig
       REAL (KIND=nag_wp)              :: abnorm, abnrm, bbnrm, eps, erbnd,    &
                                          rcnd, small, tol
       INTEGER                         :: i, ihi, ilo, info, j, lda, ldb,      &
                                          ldvr, lwork, n
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:), alphai(:), alphar(:),        &
                                          b(:,:), beta(:), lscale(:),          &
                                          rconde(:), rcondv(:), rscale(:),     &
                                          vr(:,:), work(:)
       REAL (KIND=nag_wp)              :: dummy(1,1)
       INTEGER, ALLOCATABLE            :: iwork(:)
       LOGICAL, ALLOCATABLE            :: bwork(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          abs, cmplx, max, nint
!      .. Executable Statements ..
       WRITE (nout,*) 'F08WBF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       lda = n
       ldb = n
       ldvr = n
       ALLOCATE (a(lda,n),alphai(n),alphar(n),b(ldb,n),beta(n),lscale(n), &
          rconde(n),rcondv(n),rscale(n),vr(ldvr,n),iwork(n+6),bwork(n))

!      Use routine workspace query to get optimal workspace.
       lwork = -1
!      The NAG name equivalent of dggevx is f08wbf
       CALL dggevx('Balance','No vectors (left)','Vectors (right)', &
          'Both reciprocal condition numbers',n,a,lda,b,ldb,alphar,alphai, &
          beta,dummy,1,vr,ldvr,ilo,ihi,lscale,rscale,abnrm,bbnrm,rconde, &
          rcondv,dummy,lwork,iwork,bwork,info)

!      Make sure that there is enough workspace for blocksize nb.
       lwork = max((nb+2*n)*n,nint(dummy(1,1)))
       ALLOCATE (work(lwork))

!      Read in the matrices A and B

       READ (nin,*) (a(i,1:n),i=1,n)
       READ (nin,*) (b(i,1:n),i=1,n)

!      Solve the generalized eigenvalue problem

!      The NAG name equivalent of dggevx is f08wbf
       CALL dggevx('Balance','No vectors (left)','Vectors (right)', &
          'Both reciprocal condition numbers',n,a,lda,b,ldb,alphar,alphai, &
          beta,dummy,1,vr,ldvr,ilo,ihi,lscale,rscale,abnrm,bbnrm,rconde, &
          rcondv,work,lwork,iwork,bwork,info)

       IF (info>0) THEN
          WRITE (nout,*)
          WRITE (nout,99999) 'Failure in DGGEVX. INFO =', info
       ELSE

!         Compute the machine precision, the safe range parameter
!         small and sqrt(abnrm**2+bbnrm**2)

          eps = x02ajf()
          small = x02amf()
          abnorm = f06bnf(abnrm,bbnrm)
          tol = eps*abnorm

!         Print out eigenvalues and vectors and associated condition
!         number and bounds

          DO j = 1, n

!            Print out information on the jth eigenvalue

             WRITE (nout,*)
             IF ((abs(alphar(j))+abs(alphai(j)))*small>=abs(beta(j))) THEN
                WRITE (nout,99998) 'Eigenvalue(', j, ')', &
                   ' is numerically infinite or undetermined', 'ALPHAR(', j, &
                   ') = ', alphar(j), ', ALPHAI(', j, ') = ', alphai(j), &
                   ', BETA(', j, ') = ', beta(j)
             ELSE
                IF (alphai(j)==0.0E0_nag_wp) THEN
                   WRITE (nout,99997) 'Eigenvalue(', j, ') = ', &
                      alphar(j)/beta(j)
                ELSE
                   eig = cmplx(alphar(j),alphai(j),kind=nag_wp)/ &
                      cmplx(beta(j),kind=nag_wp)
                   WRITE (nout,99996) 'Eigenvalue(', j, ') = ', eig
                END IF
             END IF
             rcnd = rconde(j)
             WRITE (nout,*)
             WRITE (nout,99995) 'Reciprocal condition number = ', rcnd
             IF (rcnd>0.0E0_nag_wp) THEN
                erbnd = tol/rcnd
                WRITE (nout,99995) 'Error bound                 = ', erbnd
             ELSE
                WRITE (nout,*) 'Error bound is infinite'
             END IF

!            Print out information on the jth eigenvector

             WRITE (nout,*)
             WRITE (nout,99994) 'Eigenvector(', j, ')'
             IF (alphai(j)==0.0E0_nag_wp) THEN
                WRITE (nout,99993) (vr(i,j),i=1,n)
             ELSE IF (alphai(j)>0.0E0_nag_wp) THEN
                WRITE (nout,99992) (vr(i,j),vr(i,j+1),i=1,n)
             ELSE
                WRITE (nout,99992) (vr(i,j-1),-vr(i,j),i=1,n)
             END IF
             rcnd = rcondv(j)
             WRITE (nout,*)
             WRITE (nout,99995) 'Reciprocal condition number = ', rcnd
             IF (rcnd>0.0E0_nag_wp) THEN
                erbnd = tol/rcnd
                WRITE (nout,99995) 'Error bound                 = ', erbnd
             ELSE
                WRITE (nout,*) 'Error bound is infinite'
             END IF
          END DO

       END IF

99999  FORMAT (1X,A,I4)
99998  FORMAT (1X,A,I2,2A/1X,2(A,I2,A,1P,E11.4),A,I2,A,1P,E11.4)
99997  FORMAT (1X,A,I2,A,1P,E11.4)
99996  FORMAT (1X,A,I2,A,'(',1P,E11.4,',',1P,E11.4,')')
99995  FORMAT (1X,A,1P,E8.1)
99994  FORMAT (1X,A,I2,A)
99993  FORMAT (1X,1P,E11.4)
99992  FORMAT (1X,'(',1P,E11.4,',',1P,E11.4,')')
    END PROGRAM f08wbfe