PROGRAM f08qufe

!      F08QUF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zgemm, ztrsen
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       COMPLEX (KIND=nag_wp)           :: alpha, beta
       REAL (KIND=nag_wp)              :: s, sep
       INTEGER                         :: i, ifail, info, lda, ldc, ldq, ldt,  &
                                          lwork, m, n
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), c(:,:), q(:,:), t(:,:),   &
                                             w(:), work(:)
       LOGICAL, ALLOCATABLE            :: select(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Intrinsic Functions ..
       INTRINSIC                          cmplx
!      .. Executable Statements ..
       WRITE (nout,*) 'F08QUF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldc = n
       lda = n
       ldq = n
       ldt = n
       lwork = (n*n)/2
       ALLOCATE (a(lda,n),c(ldc,n),q(ldq,n),t(ldt,n),w(n),work(lwork), &
          select(n))

!      Read T, Q and the logical array SELECT from data file

       READ (nin,*) (t(i,1:n),i=1,n)
       READ (nin,*)
       READ (nin,*) (q(i,1:n),i=1,n)
       READ (nin,*)
       READ (nin,*) select(1:n)

!      Compute Q * T * Q**T to find  A
       alpha = cmplx(1,kind=nag_wp)
       beta = cmplx(0,kind=nag_wp)
       CALL zgemm('N','N',n,n,n,alpha,q,ldq,t,ldt,beta,c,ldc)
       CALL zgemm('N','C',n,n,n,alpha,c,ldc,q,ldq,beta,a,lda)

!      Print Matrix A, as computed from Q * T * Q**T
!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL x04dbf('General',' ',n,n,a,lda,'Bracketed','F7.4', &
          'Matrix A created from Q*T*Q^T','Integer',rlabs,'Integer',clabs,80, &
          0,ifail)

       WRITE (nout,*)
       FLUSH (nout)

!      Reorder the Schur factor T and update the matrix Q to obtain TT and QT

!      The NAG name equivalent of ztrsen is f08quf
       CALL ztrsen('Both','Vectors',select,n,t,ldt,q,ldq,w,m,s,sep,work,lwork, &
          info)

!      Compute QT * TT * QT**T to find  A
       alpha = cmplx(1,kind=nag_wp)
       beta = cmplx(0,kind=nag_wp)
       CALL zgemm('N','N',n,n,n,alpha,q,ldq,t,ldt,beta,c,ldc)
       CALL zgemm('N','C',n,n,n,alpha,c,ldc,q,ldq,beta,a,lda)

!      Print Matrix A, as computed from QT * TT * QT**T
       ifail = 0
       CALL x04dbf('General',' ',n,n,a,lda,'Bracketed','F7.4', &
          'Matrix A created from QT*TT*QT^T','Integer',rlabs,'Integer',clabs, &
          80,0,ifail)

!      Print condition estimates

       WRITE (nout,*)
       WRITE (nout,99999) 'Condition number estimate', &
          ' of the selected cluster of eigenvalues = ', 1.0E0_nag_wp/s
       WRITE (nout,*)
       WRITE (nout,99999) 'Condition number estimate of the spec', &
          'ified invariant subspace    = ', 1.0E0_nag_wp/sep

99999  FORMAT (1X,A,A,1P,E10.2)
    END PROGRAM f08qufe