PROGRAM f08jgfe

!      F08JGF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dpteqr, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, ldz, n
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: d(:), e(:), work(:), z(:,:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08JGF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldz = n
       ALLOCATE (d(n),e(n-1),work(4*n),z(ldz,n))

!      Read T from data file

       READ (nin,*) d(1:n)
       READ (nin,*) e(1:n-1)

!      Calculate all the eigenvalues and eigenvectors of T
!      The NAG name equivalent of dpteqr is f08jgf
       CALL dpteqr('I',n,d,e,z,ldz,work,info)

       WRITE (nout,*)
       IF (info>0 .AND. info<=n) THEN
          WRITE (nout,*) 'T is not positive definite.'
       ELSE IF (info>n) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) d(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,(8F8.4))
    END PROGRAM f08jgfe