PROGRAM f08hsfe

!      F08HSF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zhbtrd, zsteqr
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, kd, ldab, ldq, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ab(:,:), q(:,:), work(:)
       REAL (KIND=nag_wp), ALLOCATABLE :: d(:), e(:), rwork(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F08HSF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd
       ldab = kd + 1
       ldq = n
       ALLOCATE (ab(ldab,n),q(ldq,n),work(n),d(n),e(n-1),rwork(2*n-2))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          DO i = 1, n
             READ (nin,*) (ab(kd+1+i-j,j),j=i,min(n,i+kd))
          END DO
       ELSE IF (uplo=='L') THEN
          DO i = 1, n
             READ (nin,*) (ab(1+i-j,j),j=max(1,i-kd),i)
          END DO
       END IF

!      Reduce A to tridiagonal form T = (Q**H)*A*Q (and form Q)
!      The NAG name equivalent of zhbtrd is f08hsf
       CALL zhbtrd('V',uplo,n,kd,ab,ldab,d,e,q,ldq,work,info)

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of zsteqr is f08jsf
       CALL zsteqr('V',n,d,e,q,ldq,rwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) d(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             q(1:n,i) = q(1:n,i)/q(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04dbf('General',' ',n,n,q,ldq,'Bracketed','F7.4', &
             'Eigenvectors','Integer',rlabs,'Integer',clabs,80,0,ifail)

       END IF

99999  FORMAT (8X,4(F7.4,11X:))
    END PROGRAM f08hsfe