PROGRAM f08hqfe

!      F08HQF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04daf, zhbevd
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, kd, ldab, ldz,    &
                                          liwork, lrwork, lwork, n
       CHARACTER (1)                   :: job, uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ab(:,:), work(:), z(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: rwork(:), w(:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F08HQF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd
       ldab = n
       ldz = n
       liwork = 5*n + 3
       lrwork = 2*n*n + 5*n + 1
       lwork = 2*n*n
       ALLOCATE (ab(ldab,n),work(lwork),z(ldz,n),rwork(lrwork),w(n), &
          iwork(liwork))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          DO i = 1, n
             READ (nin,*) (ab(kd+1+i-j,j),j=i,min(n,i+kd))
          END DO
       ELSE IF (uplo=='L') THEN
          DO i = 1, n
             READ (nin,*) (ab(1+i-j,j),j=max(1,i-kd),i)
          END DO
       END IF

       READ (nin,*) job

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of zhbevd is f08hqf
       CALL zhbevd(job,uplo,n,kd,ab,ldab,w,z,ldz,work,lwork,rwork,lrwork, &
          iwork,liwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          DO i = 1, n
             WRITE (nout,99999) i, w(i)
          END DO
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04daf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,I5,5X,2F8.4)
    END PROGRAM f08hqfe