PROGRAM f08hnfe

!      F08HNF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : ddisna, nag_wp, x02ajf, x04daf, zhbev
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
       CHARACTER (1), PARAMETER        :: uplo = 'U'
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: eerrbd, eps
       INTEGER                         :: i, ifail, info, j, kd, ldab, ldz, n
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ab(:,:), work(:), z(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: rcondz(:), rwork(:), w(:), zerrbd(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          abs, max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F08HNF Example Program Results'
       WRITE (nout,*)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd
       ldab = kd + 1
       ldz = n
       ALLOCATE (ab(ldab,n),work(n),z(ldz,n),rcondz(n),rwork(3*n-2),w(n), &
          zerrbd(n))

!      Read the upper or lower triangular part of the symmetric band
!      matrix A from data file

       IF (uplo=='U') THEN
          READ (nin,*) ((ab(kd+1+i-j,j),j=i,min(n,i+kd)),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ab(1+i-j,j),j=max(1,i-kd),i),i=1,n)
       END IF

!      Solve the band Hermitian eigenvalue problem
!      The NAG name equivalent of zhbev is f08hnf
       CALL zhbev('Vectors',uplo,n,kd,ab,ldab,w,z,ldz,work,rwork,info)

       IF (info==0) THEN

!         Print solution

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) w(1:n)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04daf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

!         Get the machine precision, EPS and compute the approximate
!         error bound for the computed eigenvalues.  Note that for
!         the 2-norm, max( abs(W(i)) ) = norm(A), and since the
!         eigenvalues are returned in ascending order
!         max( abs(W(i)) ) = max( abs(W(1)), abs(W(n)))

          eps = x02ajf()
          eerrbd = eps*max(abs(w(1)),abs(w(n)))

!         Call DDISNA (F08FLF) to estimate reciprocal condition
!         numbers for the eigenvectors
          CALL ddisna('Eigenvectors',n,n,w,rcondz,info)

!         Compute the error estimates for the eigenvectors

          DO i = 1, n
             zerrbd(i) = eerrbd/rcondz(i)
          END DO

!         Print the approximate error bounds for the eigenvalues
!         and vectors

          WRITE (nout,*)
          WRITE (nout,*) 'Error estimate for the eigenvalues'
          WRITE (nout,99998) eerrbd
          WRITE (nout,*)
          WRITE (nout,*) 'Error estimates for the eigenvectors'
          WRITE (nout,99998) zerrbd(1:n)
       ELSE
          WRITE (nout,99997) 'Failure in ZHBEV. INFO =', info
       END IF

99999  FORMAT (3X,(8F8.4))
99998  FORMAT (4X,1P,6E11.1)
99997  FORMAT (1X,A,I4)
    END PROGRAM f08hnfe