PROGRAM f08gqfe

!      F08GQF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04daf, zhpevd
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, ldz, liwork,      &
                                          lrwork, lwork, n
       CHARACTER (1)                   :: job, uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ap(:), work(:), z(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: rwork(:), w(:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08GQF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldz = n
       liwork = 5*n + 3
       lrwork = 2*n*n + 5*n + 1
       lwork = 2*n
       ALLOCATE (ap(n*(n+1)/2),work(lwork),z(ldz,n),rwork(lrwork),w(n),iwork( &
          liwork))
       READ (nin,*) uplo

!      Read A from data file

       IF (uplo=='U') THEN
          READ (nin,*) ((ap(i+j*(j-1)/2),j=i,n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
       END IF

       READ (nin,*) job

!      Calculate all the eigenvalues and eigenvectors of A

!      The NAG name equivalent of zhpevd is f08gqf
       CALL zhpevd(job,uplo,n,ap,w,z,ldz,work,lwork,rwork,lrwork,iwork,liwork, &
          info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          DO i = 1, n
             WRITE (nout,99999) i, w(i)
          END DO
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04daf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,I5,5X,2F8.4)
    END PROGRAM f08gqfe