PROGRAM f08gffe

!      F08GFF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dopgtr, dsptrd, dsteqr, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, ldq, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ap(:), d(:), e(:), q(:,:), tau(:),   &
                                          work(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08GFF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldq = n
       ALLOCATE (ap(n*(n+1)/2),d(n),e(n),q(ldq,n),tau(n),work(2*n-2))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) ((ap(i+j*(j-1)/2),j=i,n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
       END IF

!      Reduce A to tridiagonal form T = (Q**T)*A*Q
!      The NAG name equivalent of dsptrd is f08gef
       CALL dsptrd(uplo,n,ap,d,e,tau,info)

!      Form Q explicitly, storing the result in Q
!      The NAG name equivalent of dopgtr is f08gff
       CALL dopgtr(uplo,n,ap,tau,q,ldq,work,info)

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of dsteqr is f08jef
       CALL dsteqr('V',n,d,e,q,ldq,work,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) d(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             q(1:n,i) = q(1:n,i)/q(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,n,q,ldq,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,(8F8.4))
    END PROGRAM f08gffe