PROGRAM f07tvfe

!      F07TVF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, ztrrfs, ztrtrs
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
       CHARACTER (1), PARAMETER        :: diag = 'N', trans = 'N'
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, ldb, ldx, n, nrhs
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), b(:,:), work(:), x(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: berr(:), ferr(:), rwork(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F07TVF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, nrhs
       lda = n
       ldb = n
       ldx = n
       ALLOCATE (a(lda,n),b(ldb,nrhs),work(2*n),x(ldx,n),berr(nrhs), &
          ferr(nrhs),rwork(n))

!      Read A and B from data file, and copy B to X

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) (a(i,i:n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) (a(i,1:i),i=1,n)
       END IF
       READ (nin,*) (b(i,1:nrhs),i=1,n)
       x(1:n,1:nrhs) = b(1:n,1:nrhs)

!      Compute solution in the array X
!      The NAG name equivalent of ztrtrs is f07tsf
       CALL ztrtrs(uplo,trans,diag,n,nrhs,a,lda,x,ldx,info)

!      Compute backward errors and estimated bounds on the
!      forward errors

!      The NAG name equivalent of ztrrfs is f07tvf
       CALL ztrrfs(uplo,trans,diag,n,nrhs,a,lda,b,ldb,x,ldx,ferr,berr,work, &
          rwork,info)

!      Print solution

       WRITE (nout,*)
       FLUSH (nout)

!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL x04dbf('General',' ',n,nrhs,x,ldx,'Bracketed','F7.4', &
          'Solution(s)','Integer',rlabs,'Integer',clabs,80,0,ifail)

       WRITE (nout,*)
       WRITE (nout,*) 'Backward errors (machine-dependent)'
       WRITE (nout,99999) berr(1:nrhs)
       WRITE (nout,*) 'Estimated forward error bounds (machine-dependent)'
       WRITE (nout,99999) ferr(1:nrhs)

99999  FORMAT ((5X,1P,4(E11.1,7X)))
    END PROGRAM f07tvfe