PROGRAM f07hnfe

!      F07HNF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dff, zpbsv
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
       CHARACTER (1), PARAMETER        :: uplo = 'U'
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, kd, ldab, n
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ab(:,:), b(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F07HNF Example Program Results'
       WRITE (nout,*)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd
       ldab = kd + 1
       ALLOCATE (ab(ldab,n),b(n))

!      Read the upper or lower triangular part of the band matrix A
!      from data file

       IF (uplo=='U') THEN
          READ (nin,*) ((ab(kd+1+i-j,j),j=i,min(n,i+kd)),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ab(1+i-j,j),j=max(1,i-kd),i),i=1,n)
       END IF

!      Read b from data file

       READ (nin,*) b(1:n)

!      Solve the equations Ax = b for x
!      The NAG name equivalent of zpbsv is f07hnf
       CALL zpbsv(uplo,n,kd,1,ab,ldab,b,n,info)

       IF (info==0) THEN

!         Print solution

          WRITE (nout,*) 'Solution'
          WRITE (nout,99999) b(1:n)

!         Print details of factorization

          WRITE (nout,*)
          FLUSH (nout)

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          IF (uplo=='U') THEN
             CALL x04dff(n,n,0,kd,ab,ldab,'Bracketed','F7.4', &
                'Cholesky factor U','Integer',rlabs,'Integer',clabs,80,0, &
                ifail)
          ELSE IF (uplo=='L') THEN
             CALL x04dff(n,n,kd,0,ab,ldab,'Bracketed','F7.4', &
                'Cholesky factor L','Integer',rlabs,'Integer',clabs,80,0, &
                ifail)
          END IF

       ELSE
          WRITE (nout,99998) 'The leading minor of order ', info, &
             ' is not positive definite'
       END IF

99999  FORMAT ((3X,4(' (',F7.4,',',F7.4,')':)))
99998  FORMAT (1X,A,I3,A)
    END PROGRAM f07hnfe