PROGRAM f07hhfe

!      F07HHF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dpbrfs, dpbtrf, dpbtrs, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER   :: zero = 0.0E0_nag_wp
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, kd, ldab, ldafb,  &
                                          ldb, ldx, n, nrhs
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ab(:,:), afb(:,:), b(:,:), berr(:),  &
                                          ferr(:), work(:), x(:,:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F07HHF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd, nrhs
       ldab = kd + 1
       ldafb = kd + 1
       ldb = n
       ldx = n
       ALLOCATE (ab(ldab,n),afb(ldafb,n),b(ldb,nrhs),berr(nrhs),ferr(nrhs), &
          work(3*n),x(ldx,n),iwork(n))

!      Set A to zero to avoid referencing uninitialized elements

       ab(1:kd+1,1:n) = zero

!      Read A and B from data file, and copy A to AFB and B to X

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          DO i = 1, n
             READ (nin,*) (ab(kd+1+i-j,j),j=i,min(n,i+kd))
          END DO
       ELSE IF (uplo=='L') THEN
          DO i = 1, n
             READ (nin,*) (ab(1+i-j,j),j=max(1,i-kd),i)
          END DO
       END IF
       READ (nin,*) (b(i,1:nrhs),i=1,n)

       afb(1:kd+1,1:n) = ab(1:kd+1,1:n)
       x(1:n,1:nrhs) = b(1:n,1:nrhs)

!      Factorize A in the array AFB
!      The NAG name equivalent of dpbtrf is f07hdf
       CALL dpbtrf(uplo,n,kd,afb,ldafb,info)

       WRITE (nout,*)
       FLUSH (nout)
       IF (info==0) THEN

!         Compute solution in the array X
!         The NAG name equivalent of dpbtrs is f07hef
          CALL dpbtrs(uplo,n,kd,nrhs,afb,ldafb,x,ldx,info)

!         Improve solution, and compute backward errors and
!         estimated bounds on the forward errors

!         The NAG name equivalent of dpbrfs is f07hhf
          CALL dpbrfs(uplo,n,kd,nrhs,ab,ldab,afb,ldafb,b,ldb,x,ldx,ferr,berr, &
             work,iwork,info)

!         Print solution

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,nrhs,x,ldx,'Solution(s)',ifail)

          WRITE (nout,*)
          WRITE (nout,*) 'Backward errors (machine-dependent)'
          WRITE (nout,99999) berr(1:nrhs)
          WRITE (nout,*) 'Estimated forward error bounds (machine-dependent)'
          WRITE (nout,99999) ferr(1:nrhs)
       ELSE
          WRITE (nout,*) 'A is not positive definite'
       END IF

99999  FORMAT ((3X,1P,7E11.1))
    END PROGRAM f07hhfe