PROGRAM f07hbfe

!      F07HBF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dpbsvx, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
       CHARACTER (1), PARAMETER        :: uplo = 'U'
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: rcond
       INTEGER                         :: i, ifail, info, j, kd, ldab, ldafb,  &
                                          ldb, ldx, n, nrhs
       CHARACTER (1)                   :: equed
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ab(:,:), afb(:,:), b(:,:), berr(:),  &
                                          ferr(:), s(:), work(:), x(:,:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F07HBF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd, nrhs
       ldb = n
       ldx = n
       ldab = kd + 1
       ldafb = kd + 1
       ALLOCATE (ab(ldab,n),afb(ldafb,n),b(ldb,nrhs),berr(nrhs),ferr(nrhs), &
          s(n),work(3*n),x(ldx,nrhs),iwork(n))

!      Read the upper or lower triangular part of the band matrix A
!      from data file

       IF (uplo=='U') THEN
          READ (nin,*) ((ab(kd+1+i-j,j),j=i,min(n,i+kd)),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ab(1+i-j,j),j=max(1,i-kd),i),i=1,n)
       END IF

!      Read B from data file

       READ (nin,*) (b(i,1:nrhs),i=1,n)

!      Solve the equations AX = B for X
!      The NAG name equivalent of dpbsvx is f07hbf
       CALL dpbsvx('Equilibration',uplo,n,kd,nrhs,ab,ldab,afb,ldafb,equed,s,b, &
          ldb,x,ldx,rcond,ferr,berr,work,iwork,info)

       IF ((info==0) .OR. (info==n+1)) THEN

!         Print solution, error bounds, condition number and the form
!         of equilibration

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,nrhs,x,ldx,'Solution(s)',ifail)

          WRITE (nout,*)
          WRITE (nout,*) 'Backward errors (machine-dependent)'
          WRITE (nout,99999) berr(1:nrhs)
          WRITE (nout,*)
          WRITE (nout,*) 'Estimated forward error bounds (machine-dependent)'
          WRITE (nout,99999) ferr(1:nrhs)
          WRITE (nout,*)
          WRITE (nout,*) 'Estimate of reciprocal condition number'
          WRITE (nout,99999) rcond
          WRITE (nout,*)
          IF (equed=='N') THEN
             WRITE (nout,*) 'A has not been equilibrated'
          ELSE IF (equed=='Y') THEN
             WRITE (nout,*) &
                'A has been row and column scaled as diag(S)*A*diag(S)'
          END IF

          IF (info==n+1) THEN
             WRITE (nout,*)
             WRITE (nout,*) 'The matrix A is singular to working precision'
          END IF
       ELSE
          WRITE (nout,99998) 'The leading minor of order ', info, &
             ' is not positive definite'
       END IF

99999  FORMAT ((3X,1P,7E11.1))
99998  FORMAT (1X,A,I3,A)
    END PROGRAM f07hbfe