PROGRAM e04mfae

!      E04MFA Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : e04mfa, e04wbf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lcwsav = 1, liwsav = 610,            &
                                          llwsav = 120, lrwsav = 475, nin = 5, &
                                          nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: obj
       INTEGER                         :: i, ifail, iter, j, lda, liwork,      &
                                          lwork, n, nclin, sda
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:), ax(:), bl(:), bu(:),         &
                                          clamda(:), cvec(:), work(:), x(:)
       REAL (KIND=nag_wp)              :: rwsav(lrwsav)
       INTEGER, ALLOCATABLE            :: istate(:), iwork(:)
       INTEGER                         :: iwsav(liwsav)
       LOGICAL                         :: lwsav(llwsav)
       CHARACTER (80)                  :: cwsav(lcwsav)
!      .. Intrinsic Functions ..
       INTRINSIC                          max
!      .. Executable Statements ..
       WRITE (nout,*) 'E04MFA Example Program Results'

!      Skip heading in data file

       READ (nin,*)
       READ (nin,*) n, nclin
       liwork = 2*n + 3

!      The minimum LWORK for an LP problem:

       IF (0<nclin .AND. nclin<n) THEN
          lwork = 2*(nclin+1)**2 + 7*n + 5*nclin
       ELSE IF (nclin>=n) THEN
          lwork = 2*n**2 + 7*n + 5*nclin
       ELSE
          lwork = 7*n + 1
       END IF

       lda = max(1,nclin)

       IF (nclin>0) THEN
          sda = n
       ELSE
          sda = 1
       END IF

       ALLOCATE (istate(n+nclin),iwork(liwork),a(lda,sda),bl(n+nclin), &
          bu(n+nclin),cvec(n),x(n),ax(max(1,nclin)),clamda(n+nclin),work(lwork &
          ))

       READ (nin,*) cvec(1:n)
       READ (nin,*) (a(i,1:sda),i=1,nclin)
       READ (nin,*) bl(1:(n+nclin))
       READ (nin,*) bu(1:(n+nclin))
       READ (nin,*) x(1:n)

!      Initialise E04MFA using E04WBF

       ifail = 0
       CALL e04wbf('E04MFA',cwsav,lcwsav,lwsav,llwsav,iwsav,liwsav,rwsav, &
          lrwsav,ifail)

!      Solve the problem

       ifail = -1
       CALL e04mfa(n,nclin,a,lda,bl,bu,cvec,istate,x,iter,obj,ax,clamda,iwork, &
          liwork,work,lwork,lwsav,iwsav,rwsav,ifail)

       SELECT CASE (ifail)
       CASE (0:5,7:)
          WRITE (nout,*)
          WRITE (nout,99999)
          WRITE (nout,*)

          DO i = 1, n
             WRITE (nout,99998) i, istate(i), x(i), clamda(i)
          END DO

          IF (nclin>0) THEN
             WRITE (nout,*)
             WRITE (nout,*)
             WRITE (nout,99997)
             WRITE (nout,*)

             DO i = n + 1, n + nclin
                j = i - n
                WRITE (nout,99996) j, istate(i), ax(j), clamda(i)
             END DO

          END IF

          WRITE (nout,*)
          WRITE (nout,*)
          WRITE (nout,99995) obj
          WRITE (nout,*)
          WRITE (nout,*)
          WRITE (nout,99994) iter
       END SELECT

99999  FORMAT (1X,'Varbl',2X,'Istate',3X,'Value',8X,'Lagr Mult')
99998  FORMAT (1X,'V',2(1X,I3),2X,1P,G14.6,2X,1P,G12.4)
99997  FORMAT (1X,'L Con',2X,'Istate',3X,'Value',8X,'Lagr Mult')
99996  FORMAT (1X,'L',2(1X,I3),2X,1P,G14.6,2X,1P,G12.4)
99995  FORMAT (1X,'Final objective value = ',G15.7)
99994  FORMAT (1X,'Exit from problem after',1X,I6,1X,'iterations.')
    END PROGRAM e04mfae