!   D01ANF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE d01anfe_mod

!      D01ANF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER                  :: lw = 800, nout = 6
       INTEGER, PARAMETER                  :: liw = lw/2
    CONTAINS
       FUNCTION g(x)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Function Return Value ..
          REAL (KIND=nag_wp)                  :: g
!         .. Scalar Arguments ..
          REAL (KIND=nag_wp), INTENT (IN)     :: x
!         .. Intrinsic Functions ..
          INTRINSIC                              log
!         .. Executable Statements ..
          IF (x>0.0E0_nag_wp) THEN
             g = log(x)
          ELSE
             g = 0.0E0_nag_wp
          END IF

          RETURN

       END FUNCTION g
    END MODULE d01anfe_mod
    PROGRAM d01anfe

!      D01ANF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : d01anf, nag_wp, x01aaf
       USE d01anfe_mod, ONLY : g, liw, lw, nout
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: a, abserr, b, epsabs, epsrel,    &
                                              omega, pi, result
       INTEGER                             :: ifail, key
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: w(:)
       INTEGER, ALLOCATABLE                :: iw(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'D01ANF Example Program Results'

       ALLOCATE (w(lw),iw(liw))

       epsrel = 1.0E-04_nag_wp
       epsabs = 0.0E+00_nag_wp
       a = 0.0E0_nag_wp
       b = 1.0E0_nag_wp
       omega = 10.0E0_nag_wp*x01aaf(pi)
       key = 2

       ifail = -1
       CALL d01anf(g,a,b,omega,key,epsabs,epsrel,result,abserr,w,lw,iw,liw, &
          ifail)

       IF (ifail>=0) THEN
          WRITE (nout,*)
          WRITE (nout,99999) 'A     ', 'lower limit of integration', a
          WRITE (nout,99999) 'B     ', 'upper limit of integration', b
          WRITE (nout,99998) 'EPSABS', 'absolute accuracy requested', epsabs
          WRITE (nout,99998) 'EPSREL', 'relative accuracy requested', epsrel
       END IF

       IF (ifail>=0 .AND. ifail<=5) THEN
          WRITE (nout,*)
          WRITE (nout,99997) 'RESULT', 'approximation to the integral', result
          WRITE (nout,99998) 'ABSERR', 'estimate of the absolute error', &
             abserr
          WRITE (nout,99996) 'IW(1) ', 'number of subintervals used', iw(1)
       END IF

99999  FORMAT (1X,A6,' - ',A32,' = ',F10.4)
99998  FORMAT (1X,A6,' - ',A32,' = ',E9.2)
99997  FORMAT (1X,A6,' - ',A32,' = ',F9.5)
99996  FORMAT (1X,A6,' - ',A32,' = ',I4)
    END PROGRAM d01anfe