!   C05QBF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05qbfe_mod

!      C05QBF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER                  :: n = 9, nout = 6
    CONTAINS
       SUBROUTINE fcn(n,x,fvec,iuser,ruser,iflag)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (INOUT)             :: iflag
          INTEGER, INTENT (IN)                :: n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (OUT)    :: fvec(n)
          REAL (KIND=nag_wp), INTENT (INOUT)  :: ruser(*)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
          INTEGER, INTENT (INOUT)             :: iuser(*)
!         .. Executable Statements ..
          fvec(1:n) = (3.0_nag_wp-2.0_nag_wp*x(1:n))*x(1:n) + 1.0_nag_wp
          fvec(2:n) = fvec(2:n) - x(1:(n-1))
          fvec(1:(n-1)) = fvec(1:(n-1)) - 2.0_nag_wp*x(2:n)

          RETURN

       END SUBROUTINE fcn
    END MODULE c05qbfe_mod
    PROGRAM c05qbfe

!      C05QBF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05qbf, dnrm2, nag_wp, x02ajf
       USE c05qbfe_mod, ONLY : fcn, n, nout
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: fnorm, xtol
       INTEGER                             :: i, ifail, j
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: fvec(:), x(:)
       REAL (KIND=nag_wp)                  :: ruser(1)
       INTEGER                             :: iuser(1)
!      .. Intrinsic Functions ..
       INTRINSIC                              sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'C05QBF Example Program Results'

       ALLOCATE (fvec(n),x(n))

!      The following starting values provide a rough solution.

       x(1:n) = -1.0E0_nag_wp
       xtol = sqrt(x02ajf())

       ifail = -1
       CALL c05qbf(fcn,n,x,fvec,xtol,iuser,ruser,ifail)

       SELECT CASE (ifail)
       CASE (0)
!         The NAG name equivalent of dnrm2 is f06ejf
          fnorm = dnrm2(n,fvec,1)
          WRITE (nout,*)
          WRITE (nout,99999) 'Final 2-norm of the residuals =', fnorm
          WRITE (nout,*)
          WRITE (nout,*) 'Final approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       CASE (2:4)
          WRITE (nout,*)
          WRITE (nout,*) 'Approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(i),i=1,n)
       END SELECT

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,3F12.4)
    END PROGRAM c05qbfe