!   C05PCF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05pcfe_mod

!      C05PCF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER       :: factor = 100.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: four = 4.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: one = 1.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: three = 3.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: two = 2.0_nag_wp
       INTEGER, PARAMETER                  :: maxfev = 1000, mode = 2, n = 9,  &
                                              nout = 6, nprint = 0
       INTEGER, PARAMETER                  :: nr = n*(n+1)/2
       INTEGER, PARAMETER                  :: ldfjac = n
    CONTAINS
       SUBROUTINE fcn(n,x,fvec,fjac,ldfjac,iflag)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (INOUT)             :: iflag
          INTEGER, INTENT (IN)                :: ldfjac, n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: fjac(ldfjac,n), fvec(n)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
!         .. Local Scalars ..
          INTEGER                             :: k
!         .. Executable Statements ..
          IF (iflag==0) THEN

!            Insert print statements here when NPRINT is positive.

             CONTINUE
          ELSE

             IF (iflag/=2) THEN
                fvec(1:n) = (three-two*x(1:n))*x(1:n) + one
                fvec(2:n) = fvec(2:n) - x(1:(n-1))
                fvec(1:(n-1)) = fvec(1:(n-1)) - two*x(2:n)
             ELSE
                fjac(1:n,1:n) = 0.0_nag_wp

                fjac(1,1) = three - four*x(1)
                fjac(1,2) = -two
                DO k = 2, n - 1
                   fjac(k,k) = three - four*x(k)
                   fjac(k,k-1) = -one
                   fjac(k,k+1) = -two
                END DO
                fjac(n,n-1) = -one
                fjac(n,n) = three - four*x(n)

             END IF

          END IF

          RETURN

       END SUBROUTINE fcn
    END MODULE c05pcfe_mod
    PROGRAM c05pcfe

!      C05PCF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05pcf, dnrm2, nag_wp, x02ajf
       USE c05pcfe_mod, ONLY : factor, fcn, ldfjac, maxfev, mode, n, nout,     &
                               nprint, nr, one
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: fnorm, xtol
       INTEGER                             :: ifail, j, lr, nfev, njev
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: diag(:), fjac(:,:), fvec(:),     &
                                              qtf(:), r(:), x(:)
       REAL (KIND=nag_wp)                  :: w(1,1)
!      .. Intrinsic Functions ..
       INTRINSIC                              sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'C05PCF Example Program Results'

       ALLOCATE (diag(n),fjac(ldfjac,n),fvec(n),qtf(n),r(nr),x(n))

!      The following starting values provide a rough solution.

       x(1:n) = -one

       xtol = sqrt(x02ajf())
       diag(1:n) = one

       ifail = -1
       CALL c05pcf(fcn,n,x,fvec,fjac,ldfjac,xtol,maxfev,diag,mode,factor, &
          nprint,nfev,njev,r,lr,qtf,w,ifail)

       SELECT CASE (ifail)
       CASE (0)
!         The NAG name equivalent of dnrm2 is f06ejf
          fnorm = dnrm2(n,fvec,1)
          WRITE (nout,*)
          WRITE (nout,99999) 'Final 2-norm of the residuals =', fnorm
          WRITE (nout,*)
          WRITE (nout,99998) 'Number of function evaluations =', nfev
          WRITE (nout,*)
          WRITE (nout,99998) 'Number of Jacobian evaluations =', njev
          WRITE (nout,*)
          WRITE (nout,*) 'Final approximate solution'
          WRITE (nout,*)
          WRITE (nout,99997) (x(j),j=1,n)
       CASE (2:)
          WRITE (nout,*)
          WRITE (nout,*) 'Approximate solution:'
          WRITE (nout,*)
          WRITE (nout,99997) (x(j),j=1,n)
       END SELECT

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,A,I10)
99997  FORMAT (1X,3F12.4)
    END PROGRAM c05pcfe