!   C05PBF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05pbfe_mod

!      C05PBF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER       :: one = 1.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: three = 3.0_nag_wp
       REAL (KIND=nag_wp), PARAMETER       :: two = 2.0_nag_wp
       INTEGER, PARAMETER                  :: n = 9, nout = 6
       INTEGER, PARAMETER                  :: ldfjac = n
    CONTAINS
       SUBROUTINE fcn(n,x,fvec,fjac,ldfjac,iflag)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (INOUT)             :: iflag
          INTEGER, INTENT (IN)                :: ldfjac, n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: fjac(ldfjac,n), fvec(n)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
!         .. Local Scalars ..
          INTEGER                             :: k
!         .. Executable Statements ..
          IF (iflag/=2) THEN
             fvec(1:n) = (three-two*x(1:n))*x(1:n) + one
             fvec(2:n) = fvec(2:n) - x(1:(n-1))
             fvec(1:(n-1)) = fvec(1:(n-1)) - two*x(2:n)
          ELSE
             fjac(1:n,1:n) = 0.0_nag_wp

             fjac(1,1) = three - two*two*x(1)
             fjac(1,2) = -two
             DO k = 2, n - 1
                fjac(k,k) = three - two*two*x(k)
                fjac(k,k-1) = -one
                fjac(k,k+1) = -two
             END DO
             fjac(n,n-1) = -one
             fjac(n,n) = three - two*two*x(n)

          END IF

          RETURN

       END SUBROUTINE fcn
    END MODULE c05pbfe_mod
    PROGRAM c05pbfe

!      C05PBF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05pbf, dnrm2, nag_wp, x02ajf
       USE c05pbfe_mod, ONLY : fcn, ldfjac, n, nout, one
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: fnorm, xtol
       INTEGER                             :: ifail, j, lwa
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: fjac(:,:), fvec(:), x(:)
       REAL (KIND=nag_wp)                  :: wa(1)
!      .. Intrinsic Functions ..
       INTRINSIC                              sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'C05PBF Example Program Results'

       ALLOCATE (fjac(ldfjac,n),fvec(n),x(n))

!      The following starting values provide a rough solution.

       x(1:n) = -one

       xtol = sqrt(x02ajf())

       ifail = -1
       CALL c05pbf(fcn,n,x,fvec,fjac,ldfjac,xtol,wa,lwa,ifail)

       SELECT CASE (ifail)
       CASE (0)
!         The NAG name equivalent of dnrm2 is f06ejf
          fnorm = dnrm2(n,fvec,1)
          WRITE (nout,*)
          WRITE (nout,99999) 'Final 2-norm of the residuals =', fnorm
          WRITE (nout,*)
          WRITE (nout,*) 'Final approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       CASE (2:)
          WRITE (nout,*)
          WRITE (nout,*) 'Approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       END SELECT

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,3F12.4)
    END PROGRAM c05pbfe