!   C05PBA Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05pbae_mod

!      C05PBA Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER                  :: n = 9, nout = 6
       INTEGER, PARAMETER                  :: ldfjac = n
    CONTAINS
       SUBROUTINE fcn(n,x,fvec,fjac,ldfjac,iflag,iuser,ruser)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (INOUT)             :: iflag
          INTEGER, INTENT (IN)                :: ldfjac, n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: fjac(ldfjac,n), fvec(n),      &
                                                 ruser(*)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
          INTEGER, INTENT (INOUT)             :: iuser(*)
!         .. Local Scalars ..
          INTEGER                             :: k
!         .. Executable Statements ..
          IF (iflag/=2) THEN
             fvec(1:n) = (ruser(2)+ruser(3)*x(1:n))*x(1:n) - ruser(5)
             fvec(2:n) = fvec(2:n) + ruser(1)*x(1:(n-1))
             fvec(1:(n-1)) = fvec(1:(n-1)) + ruser(4)*x(2:n)
          ELSE
             fjac(1:n,1:n) = 0.0_nag_wp

             fjac(1,1) = ruser(2) + 2.0_nag_wp*ruser(3)*x(1)
             fjac(1,2) = ruser(4)
             DO k = 2, n - 1
                fjac(k,k-1) = ruser(1)
                fjac(k,k) = ruser(2) + 2.0_nag_wp*ruser(3)*x(k)
                fjac(k,k+1) = ruser(4)
             END DO
             fjac(n,n-1) = ruser(1)
             fjac(n,n) = ruser(2) + 2.0_nag_wp*ruser(3)*x(n)

          END IF

          RETURN

       END SUBROUTINE fcn
    END MODULE c05pbae_mod
    PROGRAM c05pbae

!      C05PBA Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05pba, dnrm2, nag_wp, x02ajf
       USE c05pbae_mod, ONLY : fcn, ldfjac, n, nout
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: fnorm, tol
       INTEGER                             :: ifail, j, lwa
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: fjac(:,:), fvec(:), x(:)
       REAL (KIND=nag_wp)                  :: ruser(5), wa(1)
       INTEGER                             :: iuser(1)
!      .. Intrinsic Functions ..
       INTRINSIC                              sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'C05PBA Example Program Results'

       ALLOCATE (fjac(ldfjac,n),fvec(n),x(n))

!      The following starting values provide a rough solution.

       x(1:n) = -1.0_nag_wp

!      Store the coefficients describing the system

       ruser(1:5) = (/ -1.0_nag_wp, 3.0_nag_wp, -2.0_nag_wp, -2.0_nag_wp, &
          -1.0_nag_wp/)

       tol = sqrt(x02ajf())

       ifail = -1
       CALL c05pba(fcn,n,x,fvec,fjac,ldfjac,tol,wa,lwa,iuser,ruser,ifail)

       SELECT CASE (ifail)
       CASE (0)
!         The NAG name equivalent of dnrm2 is f06ejf
          fnorm = dnrm2(n,fvec,1)
          WRITE (nout,*)
          WRITE (nout,99999) 'Final 2-norm of the residuals =', fnorm
          WRITE (nout,*)
          WRITE (nout,*) 'Final approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       CASE (2:)
          WRITE (nout,*)
          WRITE (nout,*) 'Approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       END SELECT

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,3F12.4)
    END PROGRAM c05pbae