!   C05AWF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05awfe_mod

!      C05AWF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER                  :: nout = 6
    CONTAINS
       FUNCTION f(x,iuser,ruser)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Function Return Value ..
          REAL (KIND=nag_wp)                  :: f
!         .. Scalar Arguments ..
          REAL (KIND=nag_wp), INTENT (IN)     :: x
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: ruser(*)
          INTEGER, INTENT (INOUT)             :: iuser(*)
!         .. Intrinsic Functions ..
          INTRINSIC                              exp
!         .. Executable Statements ..
          f = exp(-x) - x

          RETURN

       END FUNCTION f
    END MODULE c05awfe_mod
    PROGRAM c05awfe

!      C05AWF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05awf, nag_wp
       USE c05awfe_mod, ONLY : f, nout
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: eps, eta, x
       INTEGER                             :: ifail, k, nfmax
!      .. Local Arrays ..
       REAL (KIND=nag_wp)                  :: ruser(1)
       INTEGER                             :: iuser(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'C05AWF Example Program Results'

       WRITE (nout,*)

!      Repeat with tolerance eps set to varying powers of 10:

LOOP:  DO k = 3, 4
          eps = 10.0E0_nag_wp**(-k)
          x = 1.0E0_nag_wp
          eta = 0.0E0_nag_wp
          nfmax = 200

          ifail = -1
          CALL c05awf(x,eps,eta,f,nfmax,iuser,ruser,ifail)

          SELECT CASE (ifail)
          CASE (0)
             WRITE (nout,99999) 'With EPS = ', eps, '   root = ', x
          CASE (:-1)
             EXIT LOOP
          CASE (3,4)
             WRITE (nout,99999) 'With EPS = ', eps, ' final value = ', x
          END SELECT

       END DO LOOP

99999  FORMAT (1X,A,E10.2,A,F14.5)
    END PROGRAM c05awfe