*     G08EAF Example Program Text
*     Mark 22 Revised. NAG Copyright 2006.
*     .. Parameters ..
      INTEGER          NOUT
      PARAMETER        (NOUT=6)
      INTEGER          M, N, MAXR, LDCOV, LWRK, MSTATE, MSEED
      PARAMETER        (M=0,N=1000,MAXR=6,LDCOV=10,LWRK=34,MSTATE=200,
     +                 MSEED=1)
*     .. Local Scalars ..
      DOUBLE PRECISION CHI, DF, PROB
      INTEGER          GENID, I, IFAIL, IFLGF, J, LSEED, LSTATE, NRUNS,
     +                 SUBID
      CHARACTER        CL
*     .. Local Arrays ..
      DOUBLE PRECISION COV(LDCOV,MAXR), EX(MAXR), WRK(LWRK), X(N)
      INTEGER          NCOUNT(MAXR), SEED(MSEED), STATE(MSTATE)
*     .. External Subroutines ..
      EXTERNAL         G05KFF, G05SQF, G08EAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'G08EAF Example Program Results'
*
      IFLGF = 0
*     GENID and SUBID identify the base generator
      GENID = 1
      SUBID = 1
*     Initialize the seed
      SEED(1) = 324213
*     Initialize the generator to a repeatable sequence
      LSTATE = MSTATE
      LSEED = MSEED
      CALL G05KFF(GENID,SUBID,SEED,LSEED,STATE,LSTATE,IFLGF)
*
      DO 20 I = 1, 10
*        Generate some U(0,1) values
         CALL G05SQF(N,0.0D0,1.0D0,STATE,X,IFLGF)
*
         IF (I.EQ.1) THEN
            CL = 'F'
         ELSE IF (I.EQ.10) THEN
            CL = 'L'
         ELSE
            CL = 'I'
         END IF
*
         IFAIL = -1
*
         CALL G08EAF(CL,N,X,M,MAXR,NRUNS,NCOUNT,EX,COV,LDCOV,CHI,DF,
     +               PROB,WRK,LWRK,IFAIL)
*
         IF (CL.NE.'L' .AND. CL.NE.'l' .AND. IFAIL.NE.0) GO TO 60
*
   20 CONTINUE
*
      IF (IFAIL.EQ.0 .OR. IFAIL.EQ.10) THEN
         WRITE (NOUT,*)
         WRITE (NOUT,99999) 'Total number of runs found = ', NRUNS
         IF (IFAIL.EQ.10) WRITE (NOUT,*)
     +       ' ** Note : the number of runs requested were not found.'
         WRITE (NOUT,*)
         WRITE (NOUT,*) '                             Count'
         WRITE (NOUT,*)
     +     '          1        2        3        4        5       >5'
         WRITE (NOUT,99998) (NCOUNT(J),J=1,MAXR)
         WRITE (NOUT,*)
         WRITE (NOUT,*) '                             Expect'
         WRITE (NOUT,*)
     +     '          1        2        3        4        5       >5'
         WRITE (NOUT,99997) (EX(J),J=1,MAXR)
         WRITE (NOUT,*)
         WRITE (NOUT,*) '                       Covariance matrix'
         WRITE (NOUT,*)
     +     '          1        2        3        4        5       >5'
         DO 40 I = 1, MAXR
            WRITE (NOUT,99996) I, (COV(I,J),J=1,MAXR)
   40    CONTINUE
         WRITE (NOUT,*)
         WRITE (NOUT,99995) 'Chisq = ', CHI
         WRITE (NOUT,99994) 'DF    = ', DF
         WRITE (NOUT,99995) 'Prob  = ', PROB
      END IF
   60 CONTINUE
*
99999 FORMAT (1X,A,I10)
99998 FORMAT (3X,6I9)
99997 FORMAT (3X,6F9.2)
99996 FORMAT (1X,I2,6F9.2)
99995 FORMAT (1X,A,F10.4)
99994 FORMAT (1X,A,F7.1)
      END