*     G05HNF Example Program Text
*     Mark 22 Release. NAG Copyright 2008.
*     .. Parameters ..
      INTEGER          NOUT
      PARAMETER        (NOUT=6)
      INTEGER          NPARMX, LDCOVR, NUM
      DOUBLE PRECISION ZERO
      PARAMETER        (NPARMX=10,LDCOVR=NPARMX,NUM=1500,ZERO=0.0D0)
      INTEGER          NUM1, NREGMX
      PARAMETER        (NUM1=3000,NREGMX=10)
*     .. Local Scalars ..
      DOUBLE PRECISION DF, FAC1, HP, LGF, MEAN, TOL, XTERM
      INTEGER          I, IFAIL, IGEN, IP, IQ, K, LDX, LWORK, MAXIT, MN,
     +                 NPAR, NPAR2, NREG, NT
      LOGICAL          COPT, FCALL
      CHARACTER        DIST
*     .. Local Arrays ..
      DOUBLE PRECISION BX(10), COVR(LDCOVR,NPARMX), CVAR(100),
     +                 ETM(NUM1), HT(NUM1+10), HTM(NUM1), PARAM(NPARMX),
     +                 RVEC(40), RWSAV(9), SC(NPARMX), SE(NPARMX),
     +                 THETA(NPARMX), WORK(NUM1*3+NPARMX+NREGMX*NUM1+20*
     +                 20+1), X(NUM1,10), YT(NUM1+10)
      INTEGER          ISEED(4)
*     .. External Subroutines ..
      EXTERNAL         G05HNF, G05KBF, G13FGF, G13FHF
*     .. Intrinsic Functions ..
      INTRINSIC        DBLE, SIN
*     .. Executable Statements ..
      WRITE (NOUT,*) 'G05HNF Example Program Results'
      WRITE (NOUT,*)
*
*     Initialize the generator
      ISEED(1) = 111
      IGEN = 0
      CALL G05KBF(IGEN,ISEED)
*
*     Example using Normal errors
      LDX = NUM1
      BX(1) = 1.5D0
      BX(2) = 2.5D0
      MEAN = 3.0D0
*
      DO 20 I = 1, NUM
         FAC1 = DBLE(I)*0.01D0
         X(I,1) = 0.01D0 + 0.7D0*SIN(FAC1)
         X(I,2) = 0.5D0 + FAC1*0.1D0
         X(I,3) = 1.0D0
   20 CONTINUE
*
      NREG = 2
      MN = 1
      IP = 1
      IQ = 1
      NPAR = IP + 2*IQ + 1
*
      PARAM(1) = 0.1D0
      PARAM(2) = -0.3D0
      PARAM(3) = 0.1D0
      PARAM(4) = 0.9D0
*
      DF = 5.0D0
      DIST = 'N'
*
*     Call the routine for the first time
      FCALL = .TRUE.
      IFAIL = 0
      CALL G05HNF(DIST,800,IP,IQ,PARAM,DF,HT,YT,FCALL,RVEC,IGEN,ISEED,
     +            RWSAV,IFAIL)
*     Discard the first 800 values, and call the routine again
      FCALL = .FALSE.
      IFAIL = 0
      CALL G05HNF(DIST,NUM,IP,IQ,PARAM,DF,HT,YT,FCALL,RVEC,IGEN,ISEED,
     +            RWSAV,IFAIL)
*
      DO 60 I = 1, NUM
         XTERM = ZERO
         DO 40 K = 1, NREG
            XTERM = XTERM + X(I,K)*BX(K)
   40    CONTINUE
         IF (MN.EQ.1) THEN
            YT(I) = MEAN + XTERM + YT(I)
         ELSE
            YT(I) = XTERM + YT(I)
         END IF
   60 CONTINUE
*
      COPT = .TRUE.
*
      MAXIT = 50
      TOL = 1.0D-5
*
      DO 80 I = 1, NPAR
         THETA(I) = PARAM(I)*0.5D0
   80 CONTINUE
*
      IF (MN.EQ.1) THEN
         THETA(NPAR+MN) = MEAN*0.5D0
      END IF
*
      DO 100 I = 1, NREG
         THETA(NPAR+MN+I) = BX(I)*0.5D0
  100 CONTINUE
*
*     Fit an EGARCH model to the generated data
      LWORK = NREG*NUM + 3*NUM + 3
      NPAR2 = 1 + IQ*2 + IP + MN + NREG
      IFAIL = 0
      CALL G13FGF(DIST,YT,X,LDX,NUM,IP,IQ,NREG,MN,NPAR2,THETA,SE,SC,
     +            COVR,LDCOVR,HP,ETM,HTM,LGF,COPT,MAXIT,TOL,WORK,LWORK,
     +            IFAIL)
*     Display the output
      WRITE (NOUT,*)
      WRITE (NOUT,*) 'Normal distribution'
      WRITE (NOUT,*)
      WRITE (NOUT,*) '             Correct    Parameter   Standard'
      WRITE (NOUT,*) '             values     estimates    errors'
      DO 120 I = 1, NPAR
         WRITE (NOUT,99998) 'PARAM(', I, ')', PARAM(I), THETA(I), SE(I)
  120 CONTINUE
      IF (MN.EQ.1) THEN
         WRITE (NOUT,99999) 'Mean    ', MEAN, THETA(NPAR+1), SE(NPAR+1)
      END IF
      DO 140 I = 1, NREG
         WRITE (NOUT,99998) 'BX(', I, ')   ', BX(I), THETA(NPAR+MN+I),
     +     SE(NPAR+MN+I)
  140 CONTINUE
*
      NT = 4
      IFAIL = 0
      CALL G13FHF(NUM,NT,IP,IQ,THETA,CVAR,HTM,ETM,IFAIL)
      WRITE (NOUT,*)
      WRITE (NOUT,99997) 'Volatility forecast = ', CVAR(NT)
      WRITE (NOUT,*)
*
*     Example using Students T errors
      NREG = 2
      MN = 1
      IP = 1
      IQ = 2
      NPAR = IP + 2*IQ + 1
*
      PARAM(1) = 0.1D0
      PARAM(2) = -0.3D0
      PARAM(3) = -0.1D0
      PARAM(4) = 0.1D0
      PARAM(5) = 0.3D0
      PARAM(6) = 0.7D0
*
      DIST = 'T'
*
*     Call the routine the first time
      FCALL = .TRUE.
      IFAIL = 0
      CALL G05HNF(DIST,NUM,IP,IQ,PARAM,DF,HT,YT,FCALL,RVEC,IGEN,ISEED,
     +            RWSAV,IFAIL)
*     Call the routine the a second time
      FCALL = .FALSE.
      IFAIL = 0
      CALL G05HNF(DIST,NUM,IP,IQ,PARAM,DF,HT,YT,FCALL,RVEC,IGEN,ISEED,
     +            RWSAV,IFAIL)
*     Discard all previously generated values, and call the routine again
      FCALL = .FALSE.
      IFAIL = 0
      CALL G05HNF(DIST,NUM,IP,IQ,PARAM,DF,HT,YT,FCALL,RVEC,IGEN,ISEED,
     +            RWSAV,IFAIL)
*
      DO 180 I = 1, NUM
         XTERM = ZERO
         DO 160 K = 1, NREG
            XTERM = XTERM + X(I,K)*BX(K)
  160    CONTINUE
         IF (MN.EQ.1) THEN
            YT(I) = MEAN + XTERM + YT(I)
         ELSE
            YT(I) = XTERM + YT(I)
         END IF
  180 CONTINUE
*
      COPT = .TRUE.
      MAXIT = 50
      TOL = 1.0D-5
*
      DO 200 I = 1, NPAR
         THETA(I) = PARAM(I)*0.5D0
  200 CONTINUE
*
      THETA(NPAR+1) = DF*0.65D0
*
      IF (MN.EQ.1) THEN
         THETA(NPAR+1+MN) = MEAN*0.5D0
      END IF
*
      DO 220 I = 1, NREG
         THETA(NPAR+1+MN+I) = BX(I)*0.5D0
  220 CONTINUE
*
*     Fit an EGARCH model to the generated data
      LWORK = NREG*NUM + 3*NUM + 3
      NPAR2 = 2 + IQ*2 + IP + MN + NREG
      IFAIL = 0
      CALL G13FGF(DIST,YT,X,LDX,NUM,IP,IQ,NREG,MN,NPAR2,THETA,SE,SC,
     +            COVR,LDCOVR,HP,ETM,HTM,LGF,COPT,MAXIT,TOL,WORK,LWORK,
     +            IFAIL)
*
      WRITE (NOUT,*)
      WRITE (NOUT,*) 'Students t distribution'
      WRITE (NOUT,*)
      WRITE (NOUT,*) '             Correct    Parameter   Standard'
      WRITE (NOUT,*) '             values     estimates    errors'
      DO 240 I = 1, NPAR
         WRITE (NOUT,99998) 'PARAM(', I, ')', PARAM(I), THETA(I), SE(I)
  240 CONTINUE
      WRITE (NOUT,99999) 'DF      ', DF, THETA(NPAR+1), SE(NPAR+1)
      IF (MN.EQ.1) THEN
         WRITE (NOUT,99999) 'Mean    ', MEAN, THETA(NPAR+1+MN),
     +     SE(NPAR+1+MN)
      END IF
      DO 260 I = 1, NREG
         WRITE (NOUT,99998) 'BX(', I, ')   ', BX(I), THETA(NPAR+1+MN+I),
     +     SE(NPAR+1+MN+I)
  260 CONTINUE
*
      NT = 4
      IFAIL = 0
      CALL G13FHF(NUM,NT,IP,IQ,THETA,CVAR,HTM,ETM,IFAIL)
      WRITE (NOUT,*)
      WRITE (NOUT,99997) 'Volatility forecast = ', CVAR(NT)
      WRITE (NOUT,*)
*
99999 FORMAT (1X,A,3(F10.2,2X))
99998 FORMAT (1X,A,I1,A,3(F10.2,2X))
99997 FORMAT (1X,A,F12.2)
      END