*     G02BFF Example Program Text
*     Mark 14 Revised. NAG Copyright 1989.
*     .. Parameters ..
      INTEGER          M, N, LDX, LDSSPZ, LDRZ, LDCNT
      PARAMETER        (M=3,N=5,LDX=N,LDSSPZ=M,LDRZ=M,LDCNT=M)
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, J, NCASES
*     .. Local Arrays ..
      DOUBLE PRECISION CNT(LDCNT,M), RZ(LDRZ,M), SSPZ(LDSSPZ,M), STD(M),
     +                 X(LDX,M), XBAR(M), XMISS(M)
      INTEGER          MISS(M)
*     .. External Subroutines ..
      EXTERNAL         G02BFF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'G02BFF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) ((X(I,J),J=1,M),I=1,N)
      WRITE (NOUT,*)
      WRITE (NOUT,99999) 'Number of variables (columns) =', M
      WRITE (NOUT,99999) 'Number of cases     (rows)    =', N
      WRITE (NOUT,*)
      WRITE (NOUT,*) 'Data matrix is:-'
      WRITE (NOUT,*)
      WRITE (NOUT,99998) (J,J=1,M)
      WRITE (NOUT,99997) (I,(X(I,J),J=1,M),I=1,N)
      WRITE (NOUT,*)
*
*     Set up missing values before calling routine
*
      MISS(1) = 1
      MISS(2) = 1
      MISS(3) = 1
      XMISS(1) = 0.0D0
      XMISS(2) = -1.0D0
      XMISS(3) = 0.0D0
      IFAIL = 1
*
      CALL G02BFF(N,M,X,LDX,MISS,XMISS,XBAR,STD,SSPZ,LDSSPZ,RZ,LDRZ,
     +            NCASES,CNT,LDCNT,IFAIL)
*
      IF (IFAIL.LT.0) THEN
         WRITE (NOUT,*)
         WRITE (NOUT,99999) ' ** G02BFF returned with IFAIL = ', IFAIL
      ELSE
         IF (IFAIL.NE.0) THEN
            WRITE (NOUT,99999) 'Routine fails, IFAIL =', IFAIL
         ELSE
            WRITE (NOUT,*) 'Variable   Mean    St. dev.'
            WRITE (NOUT,99996) (I,XBAR(I),STD(I),I=1,M)
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Sums of squares and cross-products about'//
     +        ' zero'
            WRITE (NOUT,99998) (I,I=1,M)
            WRITE (NOUT,99997) (I,(SSPZ(I,J),J=1,M),I=1,M)
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Correlation-like coefficients'
            WRITE (NOUT,99998) (I,I=1,M)
            WRITE (NOUT,99997) (I,(RZ(I,J),J=1,M),I=1,M)
            WRITE (NOUT,*)
            WRITE (NOUT,99999)
     +        'Minimum number of cases used for any pair of variables: '
     +        , NCASES
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Numbers used for each pair are:'
            WRITE (NOUT,99998) (I,I=1,M)
            WRITE (NOUT,99997) (I,(CNT(I,J),J=1,M),I=1,M)
         END IF
      END IF
*
99999 FORMAT (1X,A,I5)
99998 FORMAT (1X,6I12)
99997 FORMAT (1X,I3,3F12.4)
99996 FORMAT (1X,I5,2F11.4)
      END