*     F07JVF Example Program Text
*     Mark 21 Release. NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, NRHSMX
      PARAMETER        (NMAX=50,NRHSMX=4)
      INTEGER          LDB, LDX
      PARAMETER        (LDB=NMAX,LDX=NMAX)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, INFO, J, N, NRHS
*     .. Local Arrays ..
      COMPLEX *16      B(LDB,NRHSMX), E(NMAX-1), EF(NMAX-1), WORK(NMAX),
     +                 X(LDX,NRHSMX)
      DOUBLE PRECISION BERR(NRHSMX), D(NMAX), DF(NMAX), FERR(NRHSMX),
     +                 RWORK(NMAX)
      CHARACTER        CLABS(1), RLABS(1)
*     .. External Subroutines ..
      EXTERNAL         DCOPY, F06TFF, X04DBF, ZCOPY, ZPTRFS, ZPTTRF,
     +                 ZPTTRS
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F07JVF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, NRHS
      IF (N.LE.NMAX .AND. NRHS.LE.NRHSMX) THEN
*
*        Read the lower bidiagonal part of the tridiagonal matrix A from
*        data file
*
         READ (NIN,*) (D(I),I=1,N)
         READ (NIN,*) (E(I),I=1,N-1)
*
*        Read the right hand matrix B
*
         READ (NIN,*) ((B(I,J),J=1,NRHS),I=1,N)
*
*        Copy A into DF and EF, and copy B into X
*
         CALL DCOPY(N,D,1,DF,1)
         CALL ZCOPY(N-1,E,1,EF,1)
         CALL F06TFF('General',N,NRHS,B,LDB,X,LDX)
*
*        Factorize the copy of the tridiagonal matrix A
*
         CALL ZPTTRF(N,DF,EF,INFO)
*
         IF (INFO.EQ.0) THEN
*
*           Solve the equations AX = B
*
            CALL ZPTTRS('Lower',N,NRHS,DF,EF,X,LDX,INFO)
*
*           Improve the solution and compute error estimates
*
            CALL ZPTRFS('Lower',N,NRHS,D,E,DF,EF,B,LDB,X,LDX,FERR,BERR,
     +                  WORK,RWORK,INFO)
*
*           Print the solution and the forward and backward error
*           estimates
*
            IFAIL = 0
            CALL X04DBF('General',' ',N,NRHS,X,LDX,'Bracketed','F7.4',
     +                  'Solution(s)','Integer',RLABS,'Integer',CLABS,
     +                  80,0,IFAIL)
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Backward errors (machine-dependent)'
            WRITE (NOUT,99999) (BERR(J),J=1,NRHS)
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Estimated forward error bounds (machine-dependent)'
            WRITE (NOUT,99999) (FERR(J),J=1,NRHS)
         ELSE
            WRITE (NOUT,99998) 'The leading minor of order ', INFO,
     +        ' is not positive definite'
         END IF
      ELSE
         WRITE (NOUT,*) 'NMAX and/or NRHSMX too small'
      END IF
*
99999 FORMAT ((3X,1P,7E11.1))
99998 FORMAT (1X,A,I3,A)
      END