*     F07CEF Example Program Text
*     Mark 21 Release. NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, NRHSMX
      PARAMETER        (NMAX=50,NRHSMX=4)
      INTEGER          LDB
      PARAMETER        (LDB=NMAX)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, INFO, J, N, NRHS
*     .. Local Arrays ..
      DOUBLE PRECISION B(LDB,NRHSMX), D(NMAX), DL(NMAX-1), DU(NMAX-1),
     +                 DU2(NMAX-2)
      INTEGER          IPIV(NMAX)
*     .. External Subroutines ..
      EXTERNAL         DGTTRF, DGTTRS, X04CAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F07CEF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, NRHS
      IF (N.LE.NMAX .AND. NRHS.LE.NRHSMX) THEN
*
*        Read the tridiagonal matrix A from data file
*
         READ (NIN,*) (DU(I),I=1,N-1)
         READ (NIN,*) (D(I),I=1,N)
         READ (NIN,*) (DL(I),I=1,N-1)
*
*        Read the right hand matrix B
*
         READ (NIN,*) ((B(I,J),J=1,NRHS),I=1,N)
*
*        Factorize the tridiagonal matrix A
*
         CALL DGTTRF(N,DL,D,DU,DU2,IPIV,INFO)
*
         IF (INFO.EQ.0) THEN
*
*           Solve the equations AX = B
*
            CALL DGTTRS('No transpose',N,NRHS,DL,D,DU,DU2,IPIV,B,LDB,
     +                  INFO)
*
*           Print the solution
*
            IFAIL = 0
            CALL X04CAF('General',' ',N,NRHS,B,LDB,'Solution(s)',IFAIL)
*
         ELSE
            WRITE (NOUT,99999) 'The (', INFO, ',', INFO, ')',
     +        ' element of the factor U is zero'
         END IF
      ELSE
         WRITE (NOUT,*) 'NMAX and/or NRHSMX too small'
      END IF
*
99999 FORMAT (1X,A,I3,A,I3,A,A)
      END