*     F02GJF Example Program Text
*     Mark 14 Revised. NAG Copyright 1989.
*     .. Parameters ..
      INTEGER          NMAX, LDAR, LDAI, LDBR, LDBI, LDVR, LDVI
      PARAMETER        (NMAX=4,LDAR=NMAX,LDAI=NMAX,LDBR=NMAX,LDBI=NMAX,
     +                 LDVR=NMAX,LDVI=NMAX)
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
*     .. Local Scalars ..
      DOUBLE PRECISION EPS1
      INTEGER          I, IFAIL, J, N
      LOGICAL          MATV
*     .. Local Arrays ..
      DOUBLE PRECISION AI(LDAI,NMAX), ALFI(NMAX), ALFR(NMAX),
     +                 AR(LDAR,NMAX), BETA(NMAX), BI(LDBI,NMAX),
     +                 BR(LDBR,NMAX), VI(LDVI,NMAX), VR(LDVR,NMAX)
      INTEGER          ITER(NMAX)
*     .. External Functions ..
      DOUBLE PRECISION X02AJF
      EXTERNAL         X02AJF
*     .. External Subroutines ..
      EXTERNAL         F02GJF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F02GJF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N
      IF (N.GT.0 .AND. N.LE.NMAX) THEN
         READ (NIN,*) ((AR(I,J),AI(I,J),J=1,N),I=1,N)
         READ (NIN,*) ((BR(I,J),BI(I,J),J=1,N),I=1,N)
         EPS1 = X02AJF()
         MATV = .TRUE.
         IFAIL = 1
*
         CALL F02GJF(N,AR,LDAR,AI,LDAI,BR,LDBR,BI,LDBI,EPS1,ALFR,ALFI,
     +               BETA,MATV,VR,LDVR,VI,LDVI,ITER,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
            WRITE (NOUT,*)
            DO 20 I = 1, N
               ALFR(I) = ALFR(I)/BETA(I)
               ALFI(I) = ALFI(I)/BETA(I)
   20       CONTINUE
            WRITE (NOUT,*) 'Eigenvalues'
            WRITE (NOUT,99999) (ALFR(I),ALFI(I),I=1,N)
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Eigenvectors'
            DO 40 I = 1, N
               WRITE (NOUT,99999) (VR(I,J),VI(I,J),J=1,N)
   40       CONTINUE
         ELSE
            WRITE (NOUT,99998) IFAIL
         END IF
      ELSE
         WRITE (NOUT,99999) 'N is out of range: N = ', N
      END IF
*
99999 FORMAT (1X,4(' (',F7.3,',',F7.3,')'))
99998 FORMAT (1X,/1X,' ** F02GJF returned with IFAIL = ',I5)
      END