*     F08HQF Example Program Text.
*     Mark 20 Revised. NAG Copyright 2001.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, LDZ, LDAB
      PARAMETER        (NMAX=8,LDZ=NMAX,LDAB=NMAX)
      INTEGER          LWORK, LIWORK, LRWORK
      PARAMETER        (LWORK=2*NMAX*NMAX,LIWORK=5*NMAX+3,
     +                 LRWORK=2*NMAX*NMAX+5*NMAX+1)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, INFO, J, KD, N
      CHARACTER        JOB, UPLO
*     .. Local Arrays ..
      COMPLEX*16       AB(LDAB,NMAX), WORK(LWORK), Z(LDZ,NMAX)
      DOUBLE PRECISION RWORK(LRWORK), W(NMAX)
      INTEGER          IWORK(LIWORK)
*     .. External Subroutines ..
      EXTERNAL         X04DAF, ZHBEVD
*     .. Intrinsic Functions ..
      INTRINSIC        MAX, MIN
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F08HQF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, KD
      IF (N.LE.NMAX) THEN
*
*        Read A from data file
*
         READ (NIN,*) UPLO
         IF (UPLO.EQ.'U') THEN
            DO 20 I = 1, N
               READ (NIN,*) (AB(KD+1+I-J,J),J=I,MIN(N,I+KD))
   20       CONTINUE
         ELSE IF (UPLO.EQ.'L') THEN
            DO 40 I = 1, N
               READ (NIN,*) (AB(1+I-J,J),J=MAX(1,I-KD),I)
   40       CONTINUE
         END IF
*
         READ (NIN,*) JOB
*
*        Calculate all the eigenvalues and eigenvectors of A
*
         CALL ZHBEVD(JOB,UPLO,N,KD,AB,LDAB,W,Z,LDZ,WORK,LWORK,RWORK,
     +               LRWORK,IWORK,LIWORK,INFO)
*
         WRITE (NOUT,*)
         IF (INFO.GT.0) THEN
            WRITE (NOUT,*) 'Failure to converge.'
         ELSE
*
*           Print eigenvalues and eigenvectors
*
            WRITE (NOUT,*) 'Eigenvalues'
            DO 60 I = 1, N
               WRITE (NOUT,99999) I, W(I)
   60       CONTINUE
            WRITE (NOUT,*)
            IFAIL = 0
*
            CALL X04DAF('General',' ',N,N,Z,LDZ,'Eigenvectors',IFAIL)
*
         END IF
      END IF
      STOP
*
99999 FORMAT (3X,I5,5X,2F8.4)
      END