*     F08YFF Example Program Text
*     Mark 21 Release. NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          LDQ, LDZ, NMAX
      PARAMETER        (LDQ=1,LDZ=1,NMAX=8)
      INTEGER          LDS, LDT, LWORK
      PARAMETER        (LDS=NMAX,LDT=NMAX,LWORK=4*NMAX+16)
      LOGICAL          WANTQ, WANTZ
      PARAMETER        (WANTQ=.FALSE.,WANTZ=.FALSE.)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, IFST, ILST, INFO, J, N
*     .. Local Arrays ..
      DOUBLE PRECISION Q(LDQ,1), S(LDS,NMAX), T(LDT,NMAX), WORK(LWORK),
     +                 Z(LDZ,1)
*     .. External Subroutines ..
      EXTERNAL         DTGEXC, X04CAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F08YFF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N
      IF (N.LE.NMAX) THEN
*
*        Read S and T from data file
*
         READ (NIN,*) ((S(I,J),J=1,N),I=1,N)
         READ (NIN,*) ((T(I,J),J=1,N),I=1,N)
*
*        Read the row indices
*
         READ (NIN,*) IFST, ILST
*
*        Reorder S and T
*
         CALL DTGEXC(WANTQ,WANTZ,N,S,LDS,T,LDT,Q,LDQ,Z,LDZ,IFST,ILST,
     +               WORK,LWORK,INFO)
         IF (INFO.NE.0) THEN
            WRITE (NOUT,99999) INFO, ILST
            WRITE (NOUT,*)
         END IF
*
*        Print reordered generalized Schur form
*
         IFAIL = 0
         CALL X04CAF('General',' ',N,N,S,LDS,'Reordered Schur matrix S',
     +               IFAIL)
         WRITE (NOUT,*)
         IFAIL = 0
         CALL X04CAF('General',' ',N,N,T,LDT,'Reordered Schur matrix T',
     +               IFAIL)
*
      ELSE
         WRITE (NOUT,*) 'NMAX too small'
      END IF
      STOP
*
99999 FORMAT (' Reordering could not be completed. INFO = ',I3,' ILST ',
     +       '= ',I5)
      END