PROGRAM nag_mat_inv_ex16

      ! Example Program Text for nag_mat_inv
      ! NAG fl90, Release 4. NAG Copyright 2000.

      ! .. Use Statements ..
      USE nag_mat_inv, ONLY : nag_key_sym, nag_sym_mat_inv
      USE nag_examples_io, ONLY : nag_std_out, nag_std_in
      USE nag_write_mat, ONLY : nag_write_tri_mat
      ! .. Implicit None Statement ..
      IMPLICIT NONE
      ! .. Intrinsic Functions ..
      INTRINSIC KIND
      ! .. Parameters ..
      INTEGER, PARAMETER :: wp = KIND(1.0D0)
      ! .. Local Scalars ..
      INTEGER :: i, j, n
      REAL (wp) :: rcond
      CHARACTER (1) :: uplo
      ! .. Local Arrays ..
      COMPLEX (wp), ALLOCATABLE :: a(:)
      ! .. Executable Statements ..
      WRITE (nag_std_out,*) 'Example Program Results for nag_mat_inv_ex16'
      WRITE (nag_std_out,*)

      READ (nag_std_in,*)          ! Skip heading in data file
      READ (nag_std_in,*) n
      READ (nag_std_in,*) uplo

      ALLOCATE (a((n*(n+1))/2))    ! Allocate storage

      SELECT CASE (uplo)
      CASE ('L','l')
        DO i = 1, n
          READ (nag_std_in,*) (a(i+((2*n-j)*(j-1))/2),j=1,i)
        END DO
      CASE ('U','u')
        DO i = 1, n
          READ (nag_std_in,*) (a(i+(j*(j-1))/2),j=i,n)
        END DO
      END SELECT

      CALL nag_sym_mat_inv(nag_key_sym,uplo,a,rcond=rcond)

      CALL nag_write_tri_mat(uplo,a,format='F7.4',title='Inverse matrix')

      WRITE (nag_std_out,*)
      WRITE (nag_std_out,'(1X,A,1PE10.2)') 'Estimated condition number = ', &
       1.0_wp/rcond

      DEALLOCATE (a)               ! Deallocate storage

    END PROGRAM nag_mat_inv_ex16