PROGRAM f08jufe

!      F08JUF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : f06tff, nag_wp, x04dbf, zhetrd, zpteqr, zungtr
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, ldz, lwork, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), tau(:), work(:), z(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: d(:), e(:), rwork(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08JUF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       lda = n
       ldz = n
       lwork = 64*n
       ALLOCATE (a(lda,n),tau(n),work(lwork),z(ldz,n),d(n),e(n),rwork(4*n))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) (a(i,i:n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) (a(i,1:i),i=1,n)
       END IF

!      Reduce A to tridiagonal form T = (Q**H)*A*Q

!      The NAG name equivalent of zhetrd is f08fsf
       CALL zhetrd(uplo,n,a,lda,d,e,tau,work,lwork,info)

!      Copy A into Z

       CALL f06tff(uplo,n,n,a,lda,z,ldz)

!      Form Q explicitly, storing the result in Z

!      The NAG name equivalent of zungtr is f08ftf
       CALL zungtr(uplo,n,z,ldz,tau,work,lwork,info)

!      Calculate all the eigenvalues and eigenvectors of A

!      The NAG name equivalent of zpteqr is f08juf
       CALL zpteqr('V',n,d,e,z,ldz,rwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) d(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04dbf('General',' ',n,n,z,ldz,'Bracketed','F7.4', &
             'Eigenvectors','Integer',rlabs,'Integer',clabs,80,0,ifail)

       END IF

99999  FORMAT (8X,4(F7.4,11X:))
    END PROGRAM f08jufe