PROGRAM f08gtfe

!      F08GTF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zhptrd, zsteqr, zupgtr
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, ldq, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: ap(:), q(:,:), tau(:), work(:)
       REAL (KIND=nag_wp), ALLOCATABLE :: d(:), e(:), rwork(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08GTF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldq = n
       ALLOCATE (ap(n*(n+1)/2),q(ldq,n),tau(n),work(n-1),d(n),e(n),rwork(2*n-2 &
          ))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) ((ap(i+j*(j-1)/2),j=i,n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
       END IF

!      Reduce A to tridiagonal form T = (Q**H)*A*Q
!      The NAG name equivalent of zhptrd is f08gsf
       CALL zhptrd(uplo,n,ap,d,e,tau,info)

!      Form Q explicitly, storing the result in Q
!      The NAG name equivalent of zupgtr is f08gtf
       CALL zupgtr(uplo,n,ap,tau,q,ldq,work,info)

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of zsteqr is f08jsf
       CALL zsteqr('V',n,d,e,q,ldq,rwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) d(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             q(1:n,i) = q(1:n,i)/q(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04dbf('General',' ',n,n,q,ldq,'Bracketed','F7.4', &
             'Eigenvectors','Integer',rlabs,'Integer',clabs,80,0,ifail)

       END IF

99999  FORMAT (8X,4(F7.4,11X:))
    END PROGRAM f08gtfe