PROGRAM f08gcfe

!      F08GCF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dspevd, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, ldz, liwork,      &
                                          lwork, n
       CHARACTER (1)                   :: job, uplo
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ap(:), w(:), work(:), z(:,:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08GCF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ldz = n
       liwork = 5*n + 3
       lwork = n*n + 6*n + 1
       ALLOCATE (ap(n*(n+1)/2),w(n),work(lwork),z(ldz,n),iwork(liwork))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) ((ap(i+j*(j-1)/2),j=i,n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) ((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
       END IF

       READ (nin,*) job

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of dspevd is f08gcf
       CALL dspevd(job,uplo,n,ap,w,z,ldz,work,lwork,iwork,liwork,info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          WRITE (nout,99999) w(1:n)
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             z(1:n,i) = z(1:n,i)/z(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04caf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,(8F8.4))
    END PROGRAM f08gcfe