PROGRAM f08fqfe

!      F08FQF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04daf, zheevd
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, liwork, lrwork, &
                                          lwork, n
       CHARACTER (1)                   :: job, uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), work(:)
       REAL (KIND=nag_wp), ALLOCATABLE :: rwork(:), w(:)
       INTEGER, ALLOCATABLE            :: iwork(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F08FQF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       lda = n
       liwork = 5*n + 3
       lrwork = 2*n*n + 5*n + 1
       lwork = n*(n+2)
       ALLOCATE (a(lda,n),work(lwork),rwork(lrwork),w(n),iwork(liwork))
       READ (nin,*) uplo

!      Read A from data file

       IF (uplo=='U') THEN
          READ (nin,*) (a(i,i:n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) (a(i,1:i),i=1,n)
       END IF

       READ (nin,*) job

!      Calculate all the eigenvalues and eigenvectors of A
!      The NAG name equivalent of zheevd is f08fqf
       CALL zheevd(job,uplo,n,a,lda,w,work,lwork,rwork,lrwork,iwork,liwork, &
          info)

       WRITE (nout,*)
       IF (info>0) THEN
          WRITE (nout,*) 'Failure to converge.'
       ELSE

!         Print eigenvalues and eigenvectors

          WRITE (nout,*) 'Eigenvalues'
          DO i = 1, n
             WRITE (nout,99999) i, w(i)
          END DO
          WRITE (nout,*)
          FLUSH (nout)

!         Normalize the eigenvectors
          DO i = 1, n
             a(1:n,i) = a(1:n,i)/a(1,i)
          END DO

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04daf('General',' ',n,n,a,lda,'Eigenvectors',ifail)

       END IF

99999  FORMAT (3X,I5,5X,2F8.4)
    END PROGRAM f08fqfe