PROGRAM f07wsfe

!      F07WSF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zpftrf, zpftrs
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, ldb, lena, n, nrhs
       CHARACTER (1)                   :: transr, uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:), b(:,:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F07WSF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, nrhs, uplo, transr

       lena = n*(n+1)/2
       ldb = n
       ALLOCATE (a(lena),b(ldb,nrhs))

!      Read A and B from data file
       READ (nin,*) a(1:lena)
       DO i = 1, n
          READ (nin,*) b(i,1:nrhs)
       END DO

!      Factorize A
!      The NAG name equivalent of zpftrf is f07wrf
       CALL zpftrf(transr,uplo,n,a,info)

       WRITE (nout,*)
       FLUSH (nout)
       IF (info==0) THEN

!         Compute solution
!         The NAG name equivalent of zpftrs is f07wsf
          CALL zpftrs(transr,uplo,n,nrhs,a,b,ldb,info)

!         Print solution
          ifail = 0
          CALL x04dbf('General',' ',n,nrhs,b,ldb,'Bracketed','F7.4', &
             'Solution(s)','Integer',rlabs,'Integer',clabs,80,0,ifail)

       ELSE
          WRITE (nout,*) 'A is not positive definite'
       END IF

    END PROGRAM f07wsfe