PROGRAM f07mrfe

!      F07MRF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zhetrf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, lwork, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), work(:)
       INTEGER, ALLOCATABLE            :: ipiv(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F07MRF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       lda = n
       lwork = 64*n
       ALLOCATE (a(lda,n),work(lwork),ipiv(n))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          READ (nin,*) (a(i,i:n),i=1,n)
       ELSE IF (uplo=='L') THEN
          READ (nin,*) (a(i,1:i),i=1,n)
       END IF

!      Factorize A
!      The NAG name equivalent of zhetrf is f07mrf
       CALL zhetrf(uplo,n,a,lda,ipiv,work,lwork,info)

       WRITE (nout,*)
       FLUSH (nout)

!      Print details of factorization

!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL x04dbf(uplo,'Nonunit',n,n,a,lda,'Bracketed','F7.4', &
          'Details of factorization','Integer',rlabs,'Integer',clabs,80,0, &
          ifail)

!      Print pivot indices

       WRITE (nout,*)
       WRITE (nout,*) 'IPIV'
       WRITE (nout,99999) ipiv(1:n)

       IF (info/=0) WRITE (nout,*) 'The factor D is singular'

99999  FORMAT ((1X,I12,3I18))
    END PROGRAM f07mrfe