PROGRAM f07jvfe

!      F07JVF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zptrfs, zpttrf, zpttrs
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, ldb, ldx, n, nrhs
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: b(:,:), e(:), ef(:), work(:),     &
                                             x(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: berr(:), d(:), df(:), ferr(:),       &
                                          rwork(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F07JVF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, nrhs
       ldb = n
       ldx = n
       ALLOCATE (b(ldb,nrhs),e(n-1),ef(n-1),work(n),x(ldx,nrhs),berr(nrhs), &
          d(n),df(n),ferr(nrhs),rwork(n))

!      Read the lower bidiagonal part of the tridiagonal matrix A from
!      data file

       READ (nin,*) d(1:n)
       READ (nin,*) e(1:n-1)

!      Read the right hand matrix B

       READ (nin,*) (b(i,1:nrhs),i=1,n)

!      Copy A into DF and EF, and copy B into X
       df(1:n) = d(1:n)
       ef(1:n-1) = e(1:n-1)
       x(1:n,1:nrhs) = b(1:n,1:nrhs)

!      Factorize the copy of the tridiagonal matrix A
!      The NAG name equivalent of zptrrf is f07jrf
       CALL zpttrf(n,df,ef,info)

       IF (info==0) THEN

!         Solve the equations AX = B
!         The NAG name equivalent of zptrrs is f07jsf
          CALL zpttrs('Lower',n,nrhs,df,ef,x,ldx,info)

!         Improve the solution and compute error estimates
!         The NAG name equivalent of zptrfs is f07jvf
          CALL zptrfs('Lower',n,nrhs,d,e,df,ef,b,ldb,x,ldx,ferr,berr,work, &
             rwork,info)

!         Print the solution and the forward and backward error estimates

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04dbf('General',' ',n,nrhs,x,ldx,'Bracketed','F7.4', &
             'Solution(s)','Integer',rlabs,'Integer',clabs,80,0,ifail)

          WRITE (nout,*)
          WRITE (nout,*) 'Backward errors (machine-dependent)'
          WRITE (nout,99999) berr(1:nrhs)
          WRITE (nout,*)
          WRITE (nout,*) 'Estimated forward error bounds (machine-dependent)'
          WRITE (nout,99999) ferr(1:nrhs)
       ELSE
          WRITE (nout,99998) 'The leading minor of order ', info, &
             ' is not positive definite'
       END IF

99999  FORMAT ((3X,1P,7E11.1))
99998  FORMAT (1X,A,I3,A)
    END PROGRAM f07jvfe