PROGRAM f07hdfe

!      F07HDF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : dpbtrf, nag_wp, x04cef
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, j, kd, ldab, n
       CHARACTER (1)                   :: uplo
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ab(:,:)
!      .. Intrinsic Functions ..
       INTRINSIC                          max, min
!      .. Executable Statements ..
       WRITE (nout,*) 'F07HDF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, kd
       ldab = kd + 1
       ALLOCATE (ab(ldab,n))

!      Read A from data file

       READ (nin,*) uplo
       IF (uplo=='U') THEN
          DO i = 1, n
             READ (nin,*) (ab(kd+1+i-j,j),j=i,min(n,i+kd))
          END DO
       ELSE IF (uplo=='L') THEN
          DO i = 1, n
             READ (nin,*) (ab(1+i-j,j),j=max(1,i-kd),i)
          END DO
       END IF

!      Factorize A
!      The NAG name equivalent of dpbtrf is f07hdf
       CALL dpbtrf(uplo,n,kd,ab,ldab,info)

       WRITE (nout,*)
       FLUSH (nout)
       IF (info==0) THEN

!         Print factor

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0

          IF (uplo=='U') THEN

             CALL x04cef(n,n,0,kd,ab,ldab,'Factor',ifail)

          ELSE IF (uplo=='L') THEN

             CALL x04cef(n,n,kd,0,ab,ldab,'Factor',ifail)

          END IF

       ELSE
          WRITE (nout,*) 'A is not positive definite'
       END IF

    END PROGRAM f07hdfe