PROGRAM f07avfe

!      F07AVF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp, x04dbf, zgerfs, zgetrf, zgetrs
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
       CHARACTER (1), PARAMETER        :: trans = 'N'
!      .. Local Scalars ..
       INTEGER                         :: i, ifail, info, lda, ldaf, ldb, ldx, &
                                          n, nrhs
!      .. Local Arrays ..
       COMPLEX (KIND=nag_wp), ALLOCATABLE :: a(:,:), af(:,:), b(:,:), work(:), &
                                             x(:,:)
       REAL (KIND=nag_wp), ALLOCATABLE :: berr(:), ferr(:), rwork(:)
       INTEGER, ALLOCATABLE            :: ipiv(:)
       CHARACTER (1)                   :: clabs(1), rlabs(1)
!      .. Executable Statements ..
       WRITE (nout,*) 'F07AVF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n, nrhs
       lda = n
       ldaf = n
       ldb = n
       ldx = n
       ALLOCATE (a(lda,n),af(ldaf,n),b(ldb,nrhs),work(2*n),x(ldx,n), &
          berr(nrhs),ferr(nrhs),rwork(n),ipiv(n))

!      Read A and B from data file, and copy A to AF and B to X

       READ (nin,*) (a(i,1:n),i=1,n)
       READ (nin,*) (b(i,1:nrhs),i=1,n)

       af(1:n,1:n) = a(1:n,1:n)
       x(1:n,1:nrhs) = b(1:n,1:nrhs)

!      Factorize A in the array AF
!      The NAG name equivalent of zgetrf is f07arf
       CALL zgetrf(n,n,af,ldaf,ipiv,info)

       WRITE (nout,*)
       FLUSH (nout)
       IF (info==0) THEN

!         Compute solution in the array X

!         The NAG name equivalent of zgetrs is f07asf
          CALL zgetrs(trans,n,nrhs,af,ldaf,ipiv,x,ldx,info)

!         Improve solution, and compute backward errors and
!         estimated bounds on the forward errors

!         The NAG name equivalent of zgerfs is f07avf
          CALL zgerfs(trans,n,nrhs,a,lda,af,ldaf,ipiv,b,ldb,x,ldx,ferr,berr, &
             work,rwork,info)

!         Print solution

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          CALL x04dbf('General',' ',n,nrhs,x,ldx,'Bracketed','F7.4', &
             'Solution(s)','Integer',rlabs,'Integer',clabs,80,0,ifail)

          WRITE (nout,*)
          WRITE (nout,*) 'Backward errors (machine-dependent)'
          WRITE (nout,99999) berr(1:nrhs)
          WRITE (nout,*) 'Estimated forward error bounds (machine-dependent)'
          WRITE (nout,99999) ferr(1:nrhs)
       ELSE
          WRITE (nout,*) 'The factor U is singular'
       END IF

99999  FORMAT ((5X,1P,4(E11.1,7X)))
    END PROGRAM f07avfe