PROGRAM f04affe

!      F04AFF Example Program Text

!      Mark 23 Release. NAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : f03aef, f04aff, nag_wp, x02ajf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: d1, eps
       INTEGER                         :: i, id, ifail, ir, k, lda, ldb, ldbb, &
                                          ldx, n
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:,:), b(:,:), bb(:,:), p(:), x(:,:)
!      .. Executable Statements ..
       WRITE (nout,*) 'F04AFF Example Program Results'
       WRITE (nout,*)
!      Skip heading in data file
       READ (nin,*)
       READ (nin,*) n
       ir = 1
       lda = n
       ldb = n
       ldbb = n
       ldx = n
       ALLOCATE (a(lda,n),b(ldb,ir),bb(ldbb,ir),p(n),x(ldx,ir))
       READ (nin,*) (a(i,1:n),i=1,n)

!      ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
!      Cholesky decomposition
       CALL f03aef(n,a,lda,p,d1,id,ifail)

       READ (nin,*) (b(i,1:ir),i=1,n)
       eps = x02ajf()

       ifail = 0
!      Accurate solution of linear equations
       CALL f04aff(n,ir,a,lda,p,b,ldb,eps,x,ldx,bb,ldbb,k,ifail)

       WRITE (nout,*) ' Solution'
       DO i = 1, n
          WRITE (nout,99999) x(i,1:ir)
       END DO

99999  FORMAT (1X,8F9.4)
    END PROGRAM f04affe