!   D01ATF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE d01atfe_mod

!      D01ATF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER                  :: lw = 800, nout = 6
       INTEGER, PARAMETER                  :: liw = lw/4
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: pi
    CONTAINS
       SUBROUTINE f(x,fv,n)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Scalar Arguments ..
          INTEGER, INTENT (IN)                :: n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (OUT)    :: fv(n)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
!         .. Intrinsic Functions ..
          INTRINSIC                              sin, sqrt
!         .. Executable Statements ..
          fv(1:n) = x(1:n)*sin(30.0E0_nag_wp*x(1:n))/ &
             sqrt(1.0E0_nag_wp-x(1:n)**2/(4.0E0_nag_wp*pi**2))

          RETURN

       END SUBROUTINE f
    END MODULE d01atfe_mod
    PROGRAM d01atfe

!      D01ATF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : d01atf, nag_wp, x01aaf
       USE d01atfe_mod, ONLY : f, liw, lw, nout, pi
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: a, abserr, b, epsabs, epsrel,    &
                                              result
       INTEGER                             :: ifail
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: w(:)
       INTEGER, ALLOCATABLE                :: iw(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'D01ATF Example Program Results'

       ALLOCATE (w(lw),iw(liw))

       pi = x01aaf(pi)
       epsabs = 0.0_nag_wp
       epsrel = 1.0E-04_nag_wp
       a = 0.0_nag_wp
       b = 2.0_nag_wp*pi

       ifail = -1
       CALL d01atf(f,a,b,epsabs,epsrel,result,abserr,w,lw,iw,liw,ifail)

       IF (ifail>=0) THEN
          WRITE (nout,*)
          WRITE (nout,99999) 'A     ', 'lower limit of integration', a
          WRITE (nout,99999) 'B     ', 'upper limit of integration', b
          WRITE (nout,99998) 'EPSABS', 'absolute accuracy requested', epsabs
          WRITE (nout,99998) 'EPSREL', 'relative accuracy requested', epsrel
       END IF
       IF (ifail>=0 .AND. ifail<=5) THEN
          WRITE (nout,*)
          WRITE (nout,99997) 'RESULT', 'approximation to the integral', result
          WRITE (nout,99998) 'ABSERR', 'estimate of the absolute error', &
             abserr
          WRITE (nout,99996) 'IW(1) ', 'number of subintervals used', iw(1)
       END IF

99999  FORMAT (1X,A6,' - ',A30,' = ',F10.4)
99998  FORMAT (1X,A6,' - ',A30,' = ',E9.2)
99997  FORMAT (1X,A6,' - ',A30,' = ',F9.5)
99996  FORMAT (1X,A6,' - ',A30,' = ',I4)
    END PROGRAM d01atfe