!   C05RCF Example Program Text
!   Mark 23 Release. NAG Copyright 2011.

    MODULE c05rcfe_mod

!      C05RCF Example Program Module:
!             Parameters and User-defined Routines

!      .. Use Statements ..
       USE nag_library, ONLY : nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       REAL (KIND=nag_wp), PARAMETER       :: factor = 100.0_nag_wp
       INTEGER, PARAMETER                  :: maxfev = 1000, mode = 2, n = 9,  &
                                              nout = 6, nprint = 0
    CONTAINS
       SUBROUTINE fcn(n,x,fvec,fjac,iuser,ruser,iflag)

!         .. Implicit None Statement ..
          IMPLICIT NONE
!         .. Parameters ..
          REAL (KIND=nag_wp), PARAMETER       :: coeff(5) = (/ -1.0_nag_wp,    &
                                                 3.0_nag_wp, -2.0_nag_wp,      &
                                                 -2.0_nag_wp, -1.0_nag_wp/)
!         .. Scalar Arguments ..
          INTEGER, INTENT (INOUT)             :: iflag
          INTEGER, INTENT (IN)                :: n
!         .. Array Arguments ..
          REAL (KIND=nag_wp), INTENT (INOUT)  :: fjac(n,n), fvec(n), ruser(*)
          REAL (KIND=nag_wp), INTENT (IN)     :: x(n)
          INTEGER, INTENT (INOUT)             :: iuser(*)
!         .. Local Scalars ..
          INTEGER                             :: k
!         .. Executable Statements ..
          IF (iflag==0) THEN

!            Insert print statements here when NPRINT is positive.

             CONTINUE
          ELSE IF (iflag/=2) THEN
             fvec(1:n) = (coeff(2)+coeff(3)*x(1:n))*x(1:n) - coeff(5)
             fvec(2:n) = fvec(2:n) + coeff(1)*x(1:(n-1))
             fvec(1:(n-1)) = fvec(1:(n-1)) + coeff(4)*x(2:n)
          ELSE
             fjac(1:n,1:n) = 0.0_nag_wp

             fjac(1,1) = coeff(2) + 2.0_nag_wp*coeff(3)*x(1)
             fjac(1,2) = coeff(4)
             DO k = 2, n - 1
                fjac(k,k-1) = coeff(1)
                fjac(k,k) = coeff(2) + 2.0_nag_wp*coeff(3)*x(k)
                fjac(k,k+1) = coeff(4)
             END DO
             fjac(n,n-1) = coeff(1)
             fjac(n,n) = coeff(2) + 2.0_nag_wp*coeff(3)*x(n)

          END IF

          RETURN

       END SUBROUTINE fcn
    END MODULE c05rcfe_mod
    PROGRAM c05rcfe

!      C05RCF Example Main Program

!      .. Use Statements ..
       USE nag_library, ONLY : c05rcf, dnrm2, nag_wp, x02ajf
       USE c05rcfe_mod, ONLY : factor, fcn, maxfev, mode, n, nout, nprint
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Local Scalars ..
       REAL (KIND=nag_wp)                  :: fnorm, xtol
       INTEGER                             :: ifail, j, nfev, njev
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE     :: diag(:), fjac(:,:), fvec(:),     &
                                              qtf(:), r(:), x(:)
       REAL (KIND=nag_wp)                  :: ruser(1)
       INTEGER                             :: iuser(1)
!      .. Intrinsic Functions ..
       INTRINSIC                              sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'C05RCF Example Program Results'

       ALLOCATE (diag(n),fjac(n,n),fvec(n),qtf(n),r(n*(n+1)/2),x(n))

!      The following starting values provide a rough solution.

       x(1:n) = -1.0_nag_wp

       xtol = sqrt(x02ajf())
       diag(1:n) = 1.0_nag_wp

       ifail = -1
       CALL c05rcf(fcn,n,x,fvec,fjac,xtol,maxfev,mode,diag,factor,nprint,nfev, &
          njev,r,qtf,iuser,ruser,ifail)

       SELECT CASE (ifail)
       CASE (0)
!         The NAG name equivalent of dnrm2 is f06ejf
          fnorm = dnrm2(n,fvec,1)
          WRITE (nout,*)
          WRITE (nout,99999) 'Final 2-norm of the residuals =', fnorm
          WRITE (nout,*)
          WRITE (nout,*) 'Final approximate solution'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       CASE (2:5)
          WRITE (nout,*)
          WRITE (nout,*) 'Approximate solution:'
          WRITE (nout,*)
          WRITE (nout,99998) (x(j),j=1,n)
       END SELECT

99999  FORMAT (1X,A,E12.4)
99998  FORMAT (1X,3F12.4)
    END PROGRAM c05rcfe